%let dir=your-directory;

FileName MyDir Pipe "dir ""&dir"" /B";
data _null_;
   *** Get TXT file names from the folder;
        infile MyDir lrecl=300 truncover;
        input @1 content $200. ;
        if substr(content,length(content)-3)=".txt";
        content=cats("&dir\",content);

        *** Read in every TXT file and output to "new.txt";
        infile dummy filevar=content end=done;
        file "new.txt";
        do until(done);
          input;
      put _infile_;
        end;
run;
filename mydir clear;

大人，能解析一下么？小的看不懂呀！！！

教授果然是高深的，完全看不懂您的意图，好好琢磨一下得

%let dir=your-directory;   /*指定文件路径，将“your-directory”换成实际路径*/

FileName MyDir Pipe "dir ""&dir"" /B";
data _null_;
   *** Get TXT file names from the folder;
        infile MyDir lrecl=300 truncover;
        input @1 content $200. ;   /*将指定路径下的文件夹和文件的名字读入变量content*/
        if substr(content,length(content)-3)=".txt"; /*选出txt文件*/
        content=cats("&dir\",content);    /*补全完整路径*/

        *** Read in every TXT file and output to "new.txt";
        infile dummy filevar=content end=done;  /*从变量content指定的文件读取数据*/
        file "new.txt";  /*指定输出文件*/
        do until(done);   /*对于每一个输入txt文件，读到最后就跳出do循环，目的是继续读下一个txt文件而不会造成data步结束*/
          input; /*input语句执行后，读入的值就会存到变量_infile_中*/
          put _infile_; /*将_infile_的值输出到“file”语句指定的txt文件中*/
        end;
run;
filename mydir clear;

小小的建议~
FileName MyDir Pipe "dir ""&dir.\*.txt"" /B";
下面就无需判断是否为txt文件了