data stock;
length stock $1 year R M 8;
input stock $ year  R  M ;

datalines;
1 2001 0.1 0.01
1 2002 0.2 0.02
1 2003 0.3 0.03
2 2001 0.4 0.04
2 2002 0.5 0.05
2 2003 0.6 0.06
;



proc sort data=stock;
by stock year;
run;

data stock_profit;
set stock;
by stock ;
retain stock_m stock_r;
if first.stock then do;
        stock_m = (1+m);
        stock_r = (1+r);
end;
else do;
        stock_m = stock_m * (1+m);
        stock_r = stock_r * (1+r);
        if last.stock then do;
                stock_profit = stock_r - stock_m ;
                output;
        end;       
end;
run;

非常感谢！

自己的方法：
data tmp1;set need2;
  month1=substr(month,6,2)+0;
  lgret=log(1+mros);
  lgmret=log(1+rom);
  year=substr(month,1,4)+0;
  run;
  proc sort;by stock year;run;
  proc means  noprint;
var lgret lgmret;
by stock year;
output out=ret0112 sum=tlgret tlgmret;run;
data ret0112;set ret0112;
ret0112_raw=exp(tlgret)-1;
ret0112_adj=exp(tlgret)-exp(tlgmret);
run;
data ret0112;set ret0112(keep=stock year ret0112_raw ret0112_adj);
where 2000<year<2011;
run;

这个其实只需要一步就够了

proc sql;
  create table return as
  select stock, exp(sum(log(1+R)))-exp(sum(log(1+M))) as return
  from stock
  group by stock;
quit;

确实是好方法!