call symput("n",length(name));

数据集变量和宏变量是两个概念，在同一个data step中不可使用数据集的变量给宏变量赋值，因为在run;语句提交前，宏变量还不存在。
你提的第一个问题可以这样写, 但是abc只能代表一个字符串或者是一个宏变量，不是数据集变量。
%let len=%sysfunc(length(abc));
%put &len;
第二个问题，可以这样写
data test;
set test1;
n=length(name);
call symput('n',n);
run;
%chage(&n);

太感谢您了，您从根本上解决了我心中的疑惑，如果有多个变量需要调用的话，比如宏中有两个变量。那么就需要在data步骤里面用两次 call symput()函数来调用这两个参数对吧？还有就是我用call symput()函数，运行的结果是只把最后一个观测的变量的values传出去了，而不是每一个都传出去了。怎么回事儿呢？请看下面这个例子：proc sql;
create table customer(
id int,
name char(50)
)
;
data test1;
input id name $;
datalines;
1 wang
2 lei
3 wency
4 lucy
5 jacky
;
run;

data test;
set test1;
call symput('id',id);
call symput('name',name);
run;
%chage(&id,&name);
%macro chage(id,name);
proc sql;
insert into customer (id,name) values (&id,&name);
%mend;

我想把test1的值保存在test里面的同事还保存到表customer中，就用了这个宏。有两个问题，第一 values后面跟的参数总是报错，说格式不对。第二，就算运行成功 customer表里面也只有一个值，就是test1的最后一个观测。5 jacky。 我该怎么办才能把所有记录都保存呢，难道symput只能读取最后一个观测？

value报错，是因为name在customer表中是字符型的，你需要用双引号引起来。
第二个问题的方法有很多，我这只是其中一种，未必是最优，仅供参考。
proc sql noprint;
create table customer(
id int,
name char(50)
)
;
quit;

data test1;
input id name $;
datalines;
1 wang
2 lei
3 wency
4 lucy
5 jacky
;
run;

data test;
set test1 nobs=total end=last;
call symput(cats('id',_N_),id);
call symput(cats('name',_N_),name);
if last then call symput('total',total);
run;
%put &total;


%macro chage(id,name,obsnum);
proc sql;
%do i=1 %to &obsnum;
insert into customer (id,name) values (&&id&i,"&&name&i");
%end;
quit;
%mend;
%chage(id,name,&total);

我不知道该如何谢谢你，我刚注册分数太少了。1023141064我qq有什么事情安排小弟，小弟万死不辞。