/* Trend and Seasonal Analysis */

   proc timeseries data=sashelp.air out=series
                   outtrend=trend outseason=season print=seasons;
      id date interval=qtr accumulate=avg;
      var air;
      season mean median min max;
      trend sum mean median min max;
   run;

   title1 "Trend Statistics";
   legend1 value=("Maximum" "Mean" "Median" "Minimum");
   symbol interpol=join;
   axis2 label=none;
   proc gplot data=trend;
      plot max    *date
           mean   *date
           median *date
           min    *date
           / overlay vaxis=axis2 legend=legend1;
    run;

   title1 "Trend Statistics for 2nd Season";
   proc gchart data=trend;
      where _season_ = 2;
      vbar date / sumvar=sum discrete;
   run;
   quit;

   data trend;
      set trend;
      year = year(date);
   run;

   title1 "Trend Statistics by Year";
   symbol interpol=spline;
   axis1 value=('Qtr 1' 'Qtr 2' 'Qtr 3' 'Qtr 4' ) minor=none;
   proc gplot data=trend;
     plot mean*_season_=year / haxis=axis1;
   run;

   title1 "Seasonal Statistics";
   legend1 value=("Maximum" "Mean" "Median" "Minimum");
   symbol interpol=spline;
   axis1 value=('Qtr 1' 'Qtr 2' 'Qtr 3' 'Qtr 4' ) minor=none;
   axis2 label=none;
   proc gplot data=season;
      plot max    *_season_
           mean   *_season_
           median *_season_
           min    *_season_
           / overlay haxis=axis1 vaxis=axis2 legend=legend1;
   run;