不是应该用format功能就可以了吗？
当然数据本身没有改变，改变的是display，如果真的要数据也要改，将50w条记录里面的某一列的数值，比如10020全部变成“陈家村”的话，那就要写data step或者用proc sql 更快一点把

LZ说的是不是这样。。。或者：
proc sql;
create table test4 as select a.name,b.text from test2 a inner join test1 b on a.id=b.id;
quit;
run;

data MainTable; /* main table */
   input ID City_Code District_code Admin_code;
datalines;
1001 100 101 10020
1002 200 102 20031
1003 300 103 30022
1005 500 104 50010
; run;


data Admin; /* lookup table for admin name */
input Admin_code AdminName $15.;
datalines;
10020 AdminName1
20031 AdminName2
30022 AdminName3
40031 AdminName4
50010 AdminName5
; run;

Data City;  /* lookup table for city */
input City_code CityName $15.;
datalines;
100 CityName1
200 CityName2
300 CityName3
400 CityName4
500 CityName5
; run;

/* Create a format table for admin */
data Admin_fmt (rename=(admin_code=Start AdminName=label));
    set Admin;
        retain fmtname 'Admin' type 'n';
run;

/* create a format table for city */
Data city_fmt (rename=(city_code=start cityName=label));
    set City;
        retain fmtname 'City' type 'n';
run;
/* create the formats for City and Admin */
proc format lib = work Cntlin = admin_fmt; run;
proc format lib = work cntlin = city_fmt; run;

/* display the results */
proc sql;
      select ID, City_code as City format=city., admin_code as Admin format=admin.
from maintable;
quit;

data MainTable_with_name (rename=(City_code = City Admin_code = Admin));
    set MainTable;
        format city_code city.;
        format admin_code admin.;
run;

正在研究这种方法，

谢谢，进一步学习