想再问下~关于一段程序的，
%macro checknobs(dsn);
data _null_;
if nobs=0 then do;
file print notitles;
put "there are no observations in &dsn";
end;
set &dsn nobs=nobs;
run;
%mend checknobs;
----------------------------------------------------------------
%macro checknobs(dsn);
data _null_;
set &dsn nobs=nobs;
if nobs=0 then do;
file print notitles;
put "there are no observations in &dsn";
end;

run;
%mend checknobs;

者是数据集是否为空集的判断，同样的两段程序，仅仅把set语句的位置变换一下，下面那段就无法运行，请问这是怎么回事呢~

这个问题涉及到数据步的“编译”和“执行”。

1. NOBS= 这个选项是SAS在数据步编译过程就能看到，并且得到所set的数据集有多少条记录。因此到了数据步的执行阶段，关于nobs的语句可以在set语句之前执行。所以上面那段程序是可以执行的。

2. 下面那段程序中，如果&dsn为空集，那么在执行set语句的时候发现&dsn中并没有数据可读，整个数据步的执行就到此结束了。
所以说SAS的运行是正常的。只不过是空集的时候，数据步在“if nobs=0”那一句之前就结束了；而在非空集的时候，“if nobs=0”的条件判断又是假的。因此FILE 和PUT那两句永远没有办法执行到。

非常感谢~

不是无法运行，只是没得到你要的结果．是先后顺序问题．
如果先set，没有数据就不把这个obs输出了．
set在后面，是先运行了put，set后没数据，这个数据就不输出了

%macro checknobs(dsn);
data _null_;
if nobs=0 then do;
call symput(“obscount”,”0″);
file print notitles;
put “there are no observations in &dsn”;
end;
else call symput(“obscount”,put(nobs,best12.));
stop;
set &dsn nobs=nobs;
run;
%if &obscount >0 %then %do;
proc print data=&dsn(obs=10);
title1 “a few observations from &dsn”;
run;
%end;
%mend checknobs;
%checknobs(SASHELP.CLASS)
%checknobs(SASHELP.DPLOG)
关于”编译“和“执行”的问题
这是网上查到的crackman的关于空集判断的宏程序，我试了下如果不加stop确实会出错，为什么会出现这个问题呢？

不加stop应该不会有错误。
这里加stop的原因是没有必要去执行set语句。

比如sashelp.class有19条记录，在执行set语句之前这个data步的目的就已经达到了，所以就没有必要去一条条读class的数据了。 没有stop语句的话，在读每一条记录之前，set前的语句就会执行一次，和执行一次的效果是一样的。