data ori_data;
input A B $ C $ D  E : YYMMDD10.;
format E YYMMDD10.;
datalines;
1  stkcd1 物业管理和其他     100  2007/12/31
1  stkcd1 房地产             200  2007/12/31
1  stkcd1 产品               300  2007/12/31
1  stkcd1 物业管理           250  2008/12/31
1  stkcd1 房地产             230  2008/12/31
1  stkcd1 产品               480  2008/12/31
2  stkcd2 服务业             120  2000/12/31
2  stkcd2 运输业务           130  2000/12/31
2  stkcd2 生物制药           140   2001/12/31
2  stkcd2 生物特征识别        150  2001/12/31
3  stkcd2 信息传播服务业      100  2003/12/31
3  stkcd2 房地产管理业        150  2003/12/31
3  stkcd2 租赁服务业          150  2003/12/31
3  stkcd2 房地产开发与经营业   300  2003/12/31
;

/*********计算每只股票每年的价值D的总和，（总和变量名还用D）*************/
proc means data=ori_data noprint;
by A E;
output out=sumdata sum=;
run;
/*****在原数据集的基础上，加上总和D/2.******/
data mergedata;
merge ori_data(in=bb )   sumdata(in=aa  rename=(d=d1)) ;
by A E;
if aa and bb;
d2=d1/2;
drop d1;
run;
/*****得到结果******/
data merge2;
retain A E B C D;
set mergedata;
if d2~=d  or _freq_=1;
keep A E B C D;
run;

嗯嗯 这次可以了~~
如果是同样的问题，但是加总的那一行是在前面呢？
300
100
200
这样的，要删除300那一行怎么办？

又改了一点，试试看。

data have;
input A B $ D;
datalines;
1 stkcd1 100
1 stkcd1 200
1 stkcd1 300
1 stkcd1 250
1 stkcd1 230
1 stkcd1 480
2 stkcd2 710
2 stkcd2 1190
2 stkcd2 140
2 stkcd2 150
3 stkcd3 100
3 stkcd3 150
3 stkcd3 150
3 stkcd3 300
4 stkcd4 100
4 stkcd4 200
4 stkcd4 100
4 stkcd4 100
; run;
proc sort data=have;  by a;  run;

data have1;
    set have;
        by a;
        lag1 = lag(D);
        lag2 = lag2(D);
        if first.a then do;
          flag=.;
          n=1;
        end;
        else n+1;
        if  D = lag1+lag2 then flag=1;
        drop lag1 lag2;
run;

proc sort data=have1 out=have2; by a descending n; run;

data have3;
    set have2;
        by a;
        lag1 = lag(D);
        lag2 = lag2(D);
        if first.a then do;
          flag1=.;
          n1=1;
        end;
        else n1+1;
        if  D = lag1+lag2 then flag1=1;
        drop lag1 lag2;
run;

proc sort data=have3; by a n; run;

data want;
   set have3;
   if flag  = 1 and n  not in(1 2) then delete;
   if flag1 = 1 and n1 not in(1 2) then delete;
   drop flag n flag1 n1;
run;

proc print data=want; run;

好的~非常感谢~

你好，我能再问你一个问题么。。先谢过了~~~
我想把Excel表中第一张表改为第二张表的形式，就是每一家公司每一年只有一行数据，每一行中有很多行业。
相当于转置，但是又有不同公司不同年份的问题，不能直接转。
而且数据很多，每家公司每年涉及的行业也不同，每一年销售比例也不一样。。

不好意思， 用的英文系统，把变量名该成了拼音，rename 做的有点麻烦，不过比较清楚。

proc transpose data=sales_ind out=sales_ind_trans (drop= _name_ _label_);
    by stkcd name year;
           var sales_percent;
            id industry;
run;

data sales_ind_trans;
    set sales_ind_trans;
    rename  Fang_DC = Fang_DC_Sales_Percent
                 PiFa_LS  = PiFa_LS_sales_percent
                  ZongHE = ZongHE_sales_percent
             SheHui_FW = SheHui_FW_sale_percent
             YunShu_CC = YunShu_CC_sale_percent;
run;

太感谢了！！你太牛了~~~