不敢肯定完全明白了LZ 的意思。

随机生成了一个２００行的数据集，运行两次下面的宏就可以了。

如果数据多，可以多运行几次， 每次只需改变一下文件名。

或者写成一个可循环的宏。

data ys;
  array a{15} a1-a15;
     do N = 1 to 200;
        do j = 1 to dim(a);
           a(j) = abs(int(normal(123+j+n)*100));
        end;
           output;
      end;               
    drop j;
run;
proc print data=ys; title 'ys'; run; title;

%macro mymacro(dsn=, dout1=, dout2=);
  data &dout1(keep=n flag a1-a15)  
       &dout2(keep=n flag a1-a15);
   array a{15} a1-a15;
   array b{15} b1-b15;
   retain b1-b15;
    if _n_ = 1 then do;
       set &dsn(firstobs=1 obs=1);  
           output &dout2;
        do i = 1 to dim(a);
            b(i) = a(i);
        end;        
     end;
    set &dsn;
       if _n_^=1 then do;
               c = 0;
            flag = 0;
          do i = 1 to 15;
              if a(i) - b(i) = 0 then do;
                      c+1;
                 flag = i;   end;
          end;
          if  c > 0 then output &dout1;
       end;
   drop i;
run;
%mend mymacro;

%mymacro(dsn=ys,  dout1=ys1, dout2=bc1);
%mymacro(dsn=ys1, dout1=ys2, dout2=bc2);

又看了一便LZ的要求，好象第二个output的条件应改为
if  c = 0 then output &dout1;

如果这样的话，运行３４次上面的宏，才可以得到０observation in dataset ys34

非常感谢各位高人的指点！！
其中改为：
     do i 1= 1 to 15;
          do i2=1 to 15;
              if a(i1) - b(i2) = 0 then do;
                      c+1;
                   end; end;
         end;
          if  c = 0 then output &dout1
检查发现存入ys1的数据是对的，但存入ys2的数据好像不对。
循环过程：
1、在数据集ys中将第一组（_n_=1）的观测，保存到数据集bc1中。
2、删除数据集ys中和bc1相同的观测，保存到ys1中。
3、将ys1的第一组观测，保存到bc2中。
4、删除ys1中和bc2相同的观测，保存到ys2
5、将ys2的第一组观测，保存到bc3
6、删除ys2中和bc3相同的观测，保存到ys3
........
直至最后一组，保存到bcn
再请教怎样用宏循环？
谢谢！！

LZ的新条件使外循环的次数减少了很多。 看不出有什么问题。

满足 c=0 的输出结果(ys1)中应该不包含bc1中的任何一个数。也就是说 bc1 中的15个数都不会出现在 ys1 中。 同样, 如果在ys2中找不到bc2里15个数中任何一个. 那么结果就是正确的。

如果上面的宏没有问题，可以做一个循环, 每次循环生成新的文件名，如 ysn, bcn. 然后调用这个宏。 还要有一个条件, 检验新生成的数据集 (ysn) 的行数是否为零，大于零则继续循环。

/* Try this one */
/* the dataset bc1 to bcn are appended together to BC */

data ys;            /* sample dataset */
    array a{15} a1-a15;
do N = 1 to 2000;
  do j = 1 to dim(a);
  a(j) = abs(int(normal(123+j+n)*100));
  end; output;
  end; drop j;
run;

%macro mymacro(dsn=, dout1=, dout2=);
data &dout1(keep=n a1-a15)  &dout2 (keep=n a1-a15);
array a{15} a1-a15;
array b{15} b1-b15;
retain b1-b15;
    if _n_ = 1 then do;
                     set &dsn(firstobs=1 obs=1);  
                     output &dout2;
                     do i = 1 to dim(a);
                     b(i) = a(i); end; end;
      set &dsn;
      if _n_^=1 then do;
               c = 0;
           do i1 = 1 to 15;
             do i2 = 1 to 15;
               if a(i1) - b(i2) = 0 then do;
                        c+1;            end;  
             end;
          end;
             if  c = 0 then output &dout1;
      end;
      drop i;
run;
%mend mymacro;

%macro mymacro2;
      %let dsn=ys; %let n1=1;    %let nobs=1;
%do %while(&nobs>0);
          %let dsn1=ys&n1;       %let dsn2=bc&n1;

   data _null_;
            dsn = "&dsn";
           dsn1 = "&dsn1";
           dsn2 = "&dsn2";
      call execute('%mymacro(dsn='||dsn||', dout1='||dsn1||', dout2='||dsn2||');');
   run;
      %let dsn=&dsn1;
      %let n1 = %eval(&n1+1);  
    proc sql noprint;
      select count(*) into :nobs
      from &dsn1;
    quit;

     proc append base=bc data=&dsn2;  run;
%end;
%mend mymacro2;

%mymacro2;

/* or use the %mymacro3 */
%macro mymacro3;
      %let dsn=ys;
      %let n1=1;   
      %let nobs=1;
  %do %while(&nobs>0);
      %let dsn1=ys&n1;      
      %let dsn2=bc&n1;
    %mymacro(dsn=&dsn, dout1=&dsn1, dout2=&dsn2);
      %let dsn=&dsn1;
      %let n1 = %eval(&n1+1);  
            proc sql noprint;
            select count(*) into :nobs
            from &dsn1;
            quit;
       proc append base=bc data=&dsn2;  run;
%end;
%mend mymacro3;
%mymacro3;

谢谢高人指教！！
按您的方法问题解决。