楼主明显过虑了，没那么复杂

可以考虑下用这个，程序中有些变量的长度可能需要调整，但你说的功能基本能够实现

filename medline "C:\medline.txt";
/*read the file*/
data a;
infile medline truncover;
informat raw $200.;
input raw;
raw = _infile_;
N = _n_;
run;
data b;
set a;
/*processing for PMID*/
informat pmid $30.;
retain PMID ;
if index(upcase(raw),'PMID-') then PMID = scan(raw,2,'-');
/*processing for description, may need to update the length of desc*/
informat desc $5000.;
retain desc " " flag1 0;
if index(upcase(raw),'AB  -') then do;
  desc = substr(raw,7);
  flag1 = 1;
end;
if index(upcase(raw),'AD  -') then flag1=0;
if desc ne " " and substr(raw,1,6)='      ' and flag1=1 then  desc = strip(desc)||' '||strip(raw);
/*processing for TI*/
informat ti $500.;
retain ti " " flag2 0;
if index(upcase(raw),'TI  -') then do;
  TI = substr(raw,7);
  flag2 = 1;
end;
if index(upcase(raw),'AB  -') then flag2 = 0;
if ti ne " " and substr(raw,1,6)='      ' and flag2=1 then  ti = strip(ti)||' '||strip(raw);
/*processing for MH*/
/* the split character is |, you can change the one that you want*/
informat mh $500.;
retain mh " " flag3 0;
if index(upcase(raw),'SB  -') then do;
  mh = "Flag";
  flag3 = 1;
end;
if index(upcase(raw),'EDAT-') then flag3 = 0;
if mh ne " " and flag3=1 and index(raw,'MH  -') then mh = strip(mh)||'|'||strip(substr(raw,7));

run;
proc sort data = b(where=(pmid ne ' '));
by pmid n;
run;
data c;
set b;
by pmid n;
if last.pmid;
mh = substr(mh,6);
keep pmid desc mh ti;
run;

呵呵，想起3年前，2010年左右写的一个89行的代码专门处理这个问题，现在一看，真是弱暴了啊。

学习了。收藏下。以备不时之需，谢谢各位