假设w1,w2,w3...都在work里，并且除了这些没有其他数据集以‘W’开头：

proc sql;
create table test1 as
select name, max(length) as len
from dictionary.columns
where libname='WORK' and memname eqt 'W'
group by 1
;
quit;

data _null_;
set test1 end=last;
length code $ 1000;
retain code;
if _n_=1 then code='data w0;length '!!strip(name)!!' $'!!strip(put(len,best.));
else code=trim(code)!!' '!!strip(name)!!' $'!!strip(put(len,best.));
if last then do;
code=trim(code)!!'; run;';
call execute(code);
end;
run;

谢谢@wwang111
里面还有个问题就是 字段有数值型的也有字符型的  不全都是字符定义的了  
会不会复杂了点o

proc sql;
create table test1 as
select name,type, max(length) as len
from dictionary.columns
where libname='WORK' and memname eqt 'W'
group by 1,2
;
quit;

data _null_;
set test1 end=last;
length code $ 1000;
retain code;
if _n_=1 then do;
if type=:'c' then code='data w0;length '!!strip(name)!!' $'!!strip(put(len,best.));
else code='data w0;length '!!strip(name)!!' '!!strip(put(len,best.));
end;
else do;
if type=:'c' then code=trim(code)!!''!!strip(name)!!' $'!!strip(put(len,best.));
else code=trim(code)!!''!!strip(name)!!' '!!strip(put(len,best.));;
end;
if last then do;
code=trim(code)!!'; run;';
call execute(code);
end;
run;

请问下  wwang111   你的
type=:'c'
中的：号是什么意思呀？

就是type的值以'c'开头，这里就相当于type='char'