不知道论坛上有没有相关的帖子，今天刚刚学习的，拿出来跟大家分享。
如果注释部分有理解错误的欢迎大家纠正哦~

*1、用first，last语句删除重复值;
data clasdata;
  input id name $ class $ ;
datalines;
3456 Amber Chem101
3456 Amber Math102
3456 Amber Math102
4567 Denise ENGL201
4567 Denise ENGL201
2345 Ginny CHEM101
2345 Ginny ENGL201
2345 Ginny MATH102
1234 Lynn CHEM101
1234 Lynn CHEM101
1234 Lynn MATH102
5678 Rick CHEM101
5678 Rick HIST300
5678 Rick HIST300
;
run;
proc sort data=clasdata;
  by name class;
run;
data dups nodups ;
*定义两个数据集，按下面的if条件输出到不同数据集;
  set clasdata ;
  by name class ;
  *first.var和last.var是SAS的两个临时变量，表示组内的第一个和最后一个变量。一般要跟在proc sort后，根据by后的变量使用;
  if first.class and last.class then output nodups;
  else output dups ;
run;
data nodups2;
  set clasdata ;
  by name class ;
  if first.class then output;
run;


*2、输出重复的观测值，使用nodupkey选项,注意：使用该选项后直接将原数据集中的重复值删除。注意dupout和out的区别;
proc sort data=clasdata dupout=dups3 nodupkey;
  by name class;
run;
*输出不重复重复的观测值。;
proc sort data=clasdata out=nodups4 nodupkey;
  by name class;
run;


*3、去掉重复的观测值使用nodup选项。;
proc sort data =Clasdata out =NODUPS5 nodup;
    by  name class;
run ;


*4、用freq统计某变量的值重复的情况;
proc freq data = Clasdata noprint ;
    table ID / out =Nodups6 (keep = ID Count where = (Count > 1)) ;
run ;
*如果要测试两个变量，则用到by选项;
proc sort data =Clasdata;
    by name class;
run ;
proc freq data =Clasdata noprint ;
    by name ;
    table class / out = DUPS7 (keep = name class Count) ;
run ;