写个宏来修改变量属性吧

data f3;
set f2;
flag=1;

var1=_COL0+0;

rename _COL1=var2;
rename _COL2=var3;
rename _COL3=var4;
rename _COL4=var5;
var6=input(_COL5,yymmdd10.);
format var6 yymmdd10.;
var7=input(_COL6,yymmdd10.);
format var7 yymmdd10.;
rename _COL7=var8;
rename _COL8=var9;
var10=input(_COL9,comma7.);
var11=input(_COL10,comma7.);
rename _COL11=var12;
rename _COL12=var13;
rename _COL13=var14;
rename _COL14=var15;

run;


但是字符型的倒是可以改成数值型，而如果原来变量是数值型，再使用的话就会变成空值

如果是格式不一致造成的无法合并，可以在proc append中加一个force选项。
我写了一个宏程序，可以导入并合并。你试下可以不，路径要稍微改一下。

%macro NEED;

%do i=1 %to 3;  /*这里的文件数量需要改为你的文件总数*/

PROC IMPORT OUT= WORK.a&i
            DATAFILE= "C:\NEED\a (&i).xls"  /*修改为你的文件路径*/
            DBMS=EXCEL REPLACE;
     RANGE="Wind资讯$";
     GETNAMES=YES;
     MIXED=NO;
     SCANTEXT=YES;
     USEDATE=YES;
     SCANTIME=YES;
RUN;

data a&i;
        set a&i;
        if _col0 = . then delete;
run;

%if %eval(&i)=1 %then
        %DO;
                proc sql;
                create table base_set as
                select * from a1;
                quit;
        %end;
%else
        %do;
                proc append base = base_set data = a&i force;
                run;
        %end;


%end ;

%mend;

%need;

如果是一个数据集的话，有数值型和字符型（日期型的变量不是数值型就是字符型，只是format的问题），mixed=yes选项可以把有字符又有数值的都转为字符型，不过一下子多个数据集不清楚。。。

你跟我写的是一样的   




WARNING: 变量 _COL1 在 BASE 和 DATA 文件中的长度不同。 (BASE 64 DATA 78)。
WARNING: 变量 _COL2 在 BASE 和 DATA 文件中的长度不同。 (BASE 34 DATA 36)。
WARNING: 由于类型不匹配，未追加变量 _COL9。
WARNING: 由于类型不匹配，未追加变量 _COL10。
WARNING: 变量 _COL11 在 BASE 和 DATA 文件中的长度不同。 (BASE 24 DATA 26)。
WARNING: 变量 _COL12 在 BASE 和 DATA 文件中的长度不同。 (BASE 8 DATA 12)。

导入所有的excel文件到SAS, output the contents, 建一个SAS DATASET包括文件名, 变量名, 数据类型, 找出哪几个变量有相同的名称,但不同的变量类型. 然后转换这些变量成字符型, 再合并.

变量只有两种类型:字符和数字型. 日期只是format, 你可以合并数据后重新改变变量类型, 再加上你要的format. 我在最后加上了你的空数据集base_set, 以免字符型数据被切.


%let inxlsx_dir=path ;
FILENAME pipedir PIPE  "dir/b ""%unquote(&inxlsx_dir.)""  " LRECL = 400 ;
data filelist;
   infile pipedir length=linelen;
   length dataname $29. ContsName $32. ;
   input excelname $varying200. linelen;
   if find(excelname,'.xlsx') ;
   dataname=scan(excelname,1,'.') ;
   ContsName=strip(DataName)||"_ct" ;
run;

data _null_;
  set filelist ;
  call execute('PROC IMPORT OUT='||strip(dataname)||' DATAFILE= "&inxlsx_dir.\'||strip(excelname)||'" DBMS=xlsx REPLACE ;GETNAMES=YES; RUN;');
  call execute('PROC CONTENTS DATA='||strip(dataname)||' OUT='||strip(ContsName)||'(KEEP=name type) NOPRINT; RUN;') ;
run;

data _null_ ;
  set filelist end=eof ;
  if _n_=1 then call execute('data all_conts; set ') ;
  call execute(ContsName) ;
  if eof then call execute(';run;') ;
run ;

proc sort data = all_conts nodup ;
  by name type ;
run;

proc sql ;
  create table typechange as
  select distinct name
  from all_conts
  group by name
  having count(*) > 1 ;
quit ;

%MACRO uniform_var(inputdata=);
    proc contents data=&inputdata. noprint out=conts(keep=name type);
    run;

    proc sql ;
          create table typeconts as
          select r1.*
          from typechange as r2 join conts as r1
          on upcase(r1.name) = upcase(r2.name) ;
        quit ;

    proc sql noprint ;
          select distinct name into: nametype separated by ' '
          from typeconts ;
        quit ;

    data _null_;
        set typeconts end=eof;
        if _n_ = 1 then call execute("data &inputdata.2; set &inputdata.;");
        if type=1 then do;
            call execute("length _"||strip(name)||" $32.; ");
            call execute("_"||strip(name)||"=put("||strip(name)||", BEST32.);");
        end;
        if type=2 then call execute("length _"||strip(name)||" $32.; _"||strip(name)||"="||strip(name)||";");
        if eof then call execute("drop &nametype ; run; ");
    run;

    data _null_;
        set typeconts end=eof;
        if _n_ = 1 then call execute("data _&inputdata.; set &inputdata.2; rename ");
        call execute(" _"||strip(name)||" = "||strip(name)||" ");
        if eof then call execute("; run; ");
    run;
%MEND uniform_var;

data _null_;
    set filelist end=eof;
    call execute('%uniform_var(inputdata='||strip(dataname)||');');
run;

data _null_;
    set filelist end=eof;
        if _n_ = 1 then call execute('data combined ; set base_set ') ;  
    call execute('_'||strip(dataname));
        if eof then call execute(' ; run ;') ;
run;

非常感谢   能否传个txt或者 word    直接复制的话很多错误   对这些语法不是很熟悉  另外   我只需要将  %let inxlsx_dir=path ; 中的path改一下就可以把

你需要改一下path. 还有就是要建一个空数集base_set, 但数据类型不能错, 要给足够length.

谢谢     我的文件基本是  a (1) a (2) a (3) 或者 加中文与数字组合后的   比如  2013上 （1）  2013上 （2）之类的    主要是对excel可以用鼠标简单的批量命名   ，   但是给我的这个程序导入为sas数据集却不能这样命名  


NOTE: CALL EXECUTE 例程生成的行。
290 + PROC CONTENTS DATA=a (99) OUT=a (99)_ct(KEEP=name type) NOPRINT; RUN;
                            --
                            22
ERROR: 文件“WORK.A.DATA”不存在。
NOTE 155-205: CALL EXECUTE 例程生成的行。
290 + PROC CONTENTS DATA=a (99) OUT=a (99)_ct(KEEP=name type) NOPRINT; RUN;
                                       --
                                       22
ERROR 22-7: 选项名称“99”无效。

NOTE 155-205: CALL EXECUTE 例程生成的行。
290 + PROC CONTENTS DATA=a (99) OUT=a (99)_ct(KEEP=name type) NOPRINT; RUN;
                                          ---
                                          22
ERROR 22-322: 语法错误，期望下列之一: ;, CENTILES, DATA, DETAILS, DIR, DIRECTORY, FMTLEN, LIB, MEMTYPE, MT,
              MTYPE, NODETAILS, NODS, NOPRINT, ORDER, OUT, OUT2, SHORT, VARNUM.

改一下这段程序, 加translate and compress去掉文件名里().

data filelist;
   infile pipedir length=linelen;
   length dataname $29. ContsName $32. ;
   input excelname $varying200. linelen;
   if find(excelname,'.xlsx') ;
   dataname=compress(translate(scan(excelname,1,'.'),' ','()')) ;
   ContsName=strip(DataName)||"_ct" ;
run;