等啊 等啊 谁能帮我解决

图的话我用过EXCEL,比较好解决

一个范例
DATA LIST FREE/bilirrubin (F8).
BEGIN DATA
25 178 15 10  90  30 280  20   58   8
20  75 85 12 158  10   6  22  103  16
170  28 240  8  16  20  80 420  36  24
70  22  14  5 130  54  25  22  15  22
50  24 143 42   4  18  44 220  54  38
135  24  78 24   4 152  68  45  38  18
120  18  30 20 360  26  12  16 310  72
48  96  32 22  55  12  10  62  46  35
15 192  20 65  42   6  60  34  14 115
  9 164  12 40  18 530  32 104  28   6
81  10  26 94  46  40  14  40
END DATA.
VAR LEVEL bilirrubin(SCALE).

* Syntax *.
OMS
/SELECT TABLES
/IF COMMANDS = 'Explore'
     SUBTYPES = 'Percentiles'
/DESTINATION FORMAT = SAV
             OUTFILE = 'C:\Temp\Octiles.sav'.
OMS
/SELECT TABLES
/IF COMMANDS = 'Explore'
     SUBTYPES = 'Case Processing Summary'
/DESTINATION VIEWER = NO.
EXAMINE
  VARIABLES=bilirrubin
  /PLOT BOXPLOT
  /PERCENTILES(12.5,25,37.5,50,62.5,75,87.5) AEMPIRICAL
  /STATISTICS NONE
  /NOTOTAL.
OMSEND.

MATRIX.
* Get octiles *.
GET Ei /VAR=@... TO @87.5 /FILE='C:\Temp\Octiles.sav'
       /MISSING=OMIT.
* Skewness: Bowley's SK2 *.
COMPUTE SK2=(Ei(6)+Ei(2)-2*Ei(4))/(Ei(6)-Ei(2)).
* Kurtosis: Moor's KR2 *.
COMPUTE KR2=(Ei(7)-Ei(5)+Ei(3)-Ei(1))/(Ei(6)-Ei(2))-1.233.
* Reports *.
PRINT Ei(4)
/FORMAT='F8.1'
/TITLE='Sample median (used for Wilcoxon signed-rank test of symmetry
around the median)'.
PRINT {SK2;KR2}
/FORMAT='F8.3'
/RLABEL='SK2','KR2'
/TITLE="Robust measures of skweness & kurtosis: Bowley's SK2 and Moor's
centered KR2".
PRINT/TITLE='SK2 Skewness: range [-1; 1]. -ve skewed to the left, +ve
skewed to the right'.
PRINT/TITLE='KR2 Kurtosis: range [-1.233; infinity]. -ve platikurtic,
+ve leptokurtic'.
END MATRIX.

TEMPORARY.
COMPUTE k=1.
AGGREGATE
  /OUTFILE=*
  MODE=ADDVARIABLES
  /BREAK=k
  /SampleMedian = MEDIAN(bilirrubin).
NPAR TEST
  /WILCOXON=SampleMedian WITH bilirrubin .
DELETE VARIABLES SampleMedian.

当然用Eviews使最快的啦

在大样本容量下，Jarque-Bera符合渐进的卡方分布，自由度为2.

0假设为skewness为0，且excess kurtosis（即kurtosis-3）亦为0。因为正态分布的期望偏度为0，期望偏度为3.

Jarque-Bera值=(N/6)*(Square(S)+Square(K-3)/4)

样本越不符合正态分布，即样本分布向左或右侧“扭曲”越厉害，Jarque-Bera值就越大。

对照自由度为2的卡方分布表，在一定显著性水平下，JB值大于对照表值，则否定0假设，即判断该样本不符合正态分布。

雅克贝拉统计量  Jarque-Bera 是分析什么问题的？

有什么用啊