比如000001只看192801到192809期间缺失的数据

做了个笨办法，结果对的，但是过程比较繁琐而已

data a;
input stk $ time $ c ;
cards;
000001      192801     0.3
000001      192802     0.4
000001      192803     0.3
000001      192804     0.4
000001      192805     0.3
000001      192806     0.4
000001      192807     0.3
000001      192809     0.4
000002      192801     0.3
000002      192802     0.8
000002      192804     0.4
000002      192805     0.3
000002      192806     0.4
000002      192807     0.3
000002      192808     0.4
;
run;

data b;
do i=1900 to 2050;
do j=1 to 12;
output;
end;
end;
run;
data b;
set b;
format k $6. ;
if j/10<1 then k=compress(i||'0'||j);
else k=compress(i||j);
run;

proc sql;
create table c as
select distinct stk,min(time) as tmin,max(time) as tmax
from a group by stk;
quit;
proc sql;
create table d as
select distinct c.stk,k
from c left join b
on tmin<=k<=tmax;
quit;
proc sql;
create table e as
select *
from d
where compress(stk||'*'||k) not in (select compress(stk||'*'||time) from a);
quit;

思路是
1）新建了一个所有年月的数据表b，我列的190001-205012所有月份
2）对原数据表按股票分类求出每个股票的最大时间和最小时间，数据表c
3）用sql拼接，按股票提取出时间位于该股票最小和最大时间之间的所有时间，数据表d4）用sql取出d表中存在而a表中不存在的时间记录即是所得

再优化一下

data a;
input stock $8. @13 month 8. @24 index 8.4;
datalines;
000001      192801     0.3
000001      192802     0.4
000001      192803     0.3
000001      192804     0.4
000001      192805     0.3
000001      192806     0.4
000001      192807     0.3
000001      192809     0.4
000002      192801     0.3
000002      192802     0.8
000002      192804     0.4
000002      192805     0.3
000002      192806     0.4
000002      192807     0.3
000002      192808     0.4
;
run;

proc sort data=a;
by stock month;
run;

data b;
set a;
retain bg_mon 0;
by stock month;
if first.stock then do;bg_mon=month;end;
if last.stock then do;
year1=input(substr(compress(put(bg_mon,8.)),1,4),8.);
month1=input(substr(compress(put(bg_mon,8.)),5,2),8.);
year2=input(substr(compress(put(month,8.)),1,4),8.);
month2=input(substr(compress(put(month,8.)),5,2),8.);

if year1=year2 then do month3=month1 to month2;
                        year3=year1;
                        if month3<10 then do;
                                        month4=input(compress(put(year3,8.))||'0'||compress(put(month3,8.)),8.);
                        end;
                        else do;
                                        month4=input(compress(put(year3,8.))||compress(put(month3,8.)),8.);
                        end;
                        output;
end;

else do year3=year1 to year2;
                        if year3=year1 then do month3=month1 to 12;
                                                if month3<10 then do;
                                                                month4=input(compress(put(year3,8.))||'0'||compress(put(month3,8.)),8.);
                                                end;
                                                else do;
                                                                month4=input(compress(put(year3,8.))||compress(put(month3,8.)),8.);
                                                end;
                                                output;
                        end;
                        else if year3=year2 then do month3=1 to month2;
                                                if month3<10 then do;
                                                                month4=input(compress(put(year3,8.))||'0'||compress(put(month3,8.)),8.);
                                                end;
                                                else do;
                                                                month4=input(compress(put(year3,8.))||compress(put(month3,8.)),8.);
                                                end;
                                                output;
                        end;
                        else do month3=1 to 12;
                                                if month3<10 then do;
                                                                month4=input(compress(put(year3,8.))||'0'||compress(put(month3,8.)),8.);
                                                end;
                                                else do;
                                                                month4=input(compress(put(year3,8.))||compress(put(month3,8.)),8.);
                                                end;
                                                output;
                        end;
                        end;

end;
keep stock month4;
rename month4=month;
run;

proc sort data=b;
by stock month;
run;

data a;
merge a(in=a) b(in=b);
by stock month;
if b;
run;

数据集a中，index缺失的便是缺失的月份

data a;
input stk $ time $ c ;
cards;
000001      192801     0.3
000001      192802     0.4
000001      192803     0.3
000001      192804     0.4
000001      192805     0.3
000001      192806     0.4
000001      192807     0.3
000001      192809     0.4
000002      192801     0.3
000002      192802     0.8
000002      192804     0.4
000002      192805     0.3
000002      192806     0.4
000002      192807     0.3
000002      192808     0.4
;
run;

data b;
do i=1900 to 2050;
do j=1 to 12;
output;
end;
end;
run;
data b;
set b;
format k $6. ;
if j/10<1 then k=compress(i||'0'||j);
else k=compress(i||j);
run;

proc sql;
create table c as
select distinct stk,min(time) as tmin,max(time) as tmax
from a group by stk;
quit;
proc sql;
create table d as
select distinct c.stk,k
from c left join b
on tmin<=k<=tmax;
quit;
proc sql;
create table e as
select *
from d
where compress(stk||'*'||k) not in (select compress(stk||'*'||time) from a);
quit;

不错啊！

Here is a simple idea.

1) build a template with all months
2) merge it with your data

Here is an example,

data template;
do stknum='000001','000002';
   do i=0 by 1 until( yymm='1sep1928'd);
     yymm=intnx('month', '1jan1928'd, i);   
     output;
   end;
  end;
   format yymm yymm7.;
   keep stknum yymm;
run;


data in;
input stknum $6. yearmon $7. v;
yymm=input(substr(yearmon,1,4)||substr(yearmon,5,2)||'01', yymmdd10.);
format yymm yymm7.;
cards;
000001 192801 0.3
000001 192802 0.4
000001 192803 0.3
000001 192804 0.4
000001 192805 0.3
000001 192806 0.4
000001 192807 0.3
000001 192809 0.4
000002 192801 0.3
000002 192802 0.8
000002 192804 0.4
000002 192805 0.3
000002 192806 0.4
000002 192807 0.3
000002 192808 0.4
;

data missing;
  merge in(in=a ) template(in=b);
  by stknum yymm;
  if a=0 and b=1;
  keep stknum yymm;
run;

proc print data=missing;
run;

题目还是挺清楚的。不同的人也有不同的思路和方法。都很不错。
在数据步里。我除了数组的概念，别的也不很理解和擅长。京剧
http://blog.sina.com.cn/s/blog_a3a92636010146h1.html

data test;
input stock $ ym $ target;
cards;
000001 192801 0.3
000001 192802 0.4
000001 192803 0.3
000001 192804 0.4
000001 192805 0.3
000001 192806 0.4
000001 192807 0.3
000001 192809 0.4
000002 192801 0.3
000002 192802 0.8
000002 192804 0.4
000002 192805 0.3
000002 192806 0.4
000002 192807 0.3
000002 192808 0.4
000003 192801 0.3
000003 192802 0.8
000003 192806 0.4
000003 192807 0.3
000003 192808 0.4
;
run;
proc sort data=test;
        by stock ym;
run;
data result;
        set test;
        by stock ym;
        fdate=input(ym,yymmn6.);/*月初*/
        if first.stock ne 1 then do;
                n=intck('month',lag1(fdate),fdate);/*上下两个月所差月份*/
                if n >1 then do;
                        do i=n-1 to 1 by -1;/*将缺失的月份输出*/
                                ym=put(intnx('month',fdate,-i),yymmn6.);
                                target=.;
                                output;/*输出*/
                        end;
                end;
        end;
        drop n i fdate;
run;

proc print data=result;
run;

Try this idea:

data a;
input stk $ time $ c ;
cards;
000001      192801     0.3
000001      192802     0.4
000001      192803     0.3
000001      192804     0.4
000001      192805     0.3
000001      192806     0.4
000001      192807     0.3
000001      192809     0.4
000002      192801     0.3
000002      192802     0.8
000002      192804     0.4
000002      192805     0.3
000002      192806     0.4
000002      192807     0.3
000002      192808     0.4
;
run;

proc sort data=a out=b (keep=stk time) nodupkey; run;

this step will give a unique time for each stock.

next, create a dummy data containing full range of time:

data c;
do time=192801 to 192809;
output;
end;
run;

next merge data c with b, by time:

proc sort data=b; by time; run;

data d;
      merge b   (in = one)
               c   (in = two);
      by time;
      if not one;
run;

proc sort data=d; by stk time; run;

look at data d if it is what you need.
Thanks.

简单的方法找出每只股票首尾月份中缺失的月份。比如如下数据：

data raw_data;
input Code $ Time V;
datalines;
000001 192801 0.3
000001 192802 0.4
000001 192806 0.4
000001 192807 0.3
000001 192808 0.2
000001 192809 0.3
000002 192801 0.3
000002 192802 0.8
000002 192804 0.4
000002 192805 0.3
000002 192806 0.4
000002 192807 0.3
000002 192808 0.4
;
run;

proc sort data=raw_data;
by Code;
run;

data missing_data;
set raw_data;
by Code;
Add_Time=Time-lag(Time)-1;
if first.Code then Add_Time=0;
else
      do i=1 to Add_Time;
                Missing_Time=Time-i;
                output;
      end;

drop Time V Add_time i;              

run;

不用宏、SQL，下面的data步方法：

在数据集中创建一个标示标量 is_missing，判断该条观测是否为缺失值的月份。

原始数据文件：data.txt


SAS代码：


运行结果：



求论坛币？

有个很笨的方法，先把股票代码筛选出来，然后给每个代码加上月份，弄个全库。
然后进行一次匹配，就可以发现哪些没有匹配上了。

都写的太复杂了，一个很步简单的data步就可以搞定了，呵呵

这个好

尝试一下：看似代码少，其实很容易错。感觉跟写C和perl一样。不是高频数据，用上边说过的先建立一个perfect主表，left join实际数据，找出缺失值输出来简单可靠。。

其实这个很简单，转置一下就行了；
data a;
input stk $ time $ c ;
cards;
000001      192801     0.3
000001      192802     0.4
000001      192803     0.3
000001      192804     0.4
000001      192805     0.3
000001      192806     0.4
000001      192807     0.3
000001      192809     0.4
000002      192801     0.3
000002      192802     0.8
000002      192804     0.4
000002      192805     0.3
000002      192806     0.4
000002      192807     0.3
000002      192808     0.4
;
run;

proc sort data= a out=b ;
  by  stk time;
run;

proc transpose data=b out=c name= var label= varlist ;
  id time;
  by stk;
  var c;
run;

proc transpose data=c out=d (rename=(_name_=time col1=C));
  by stk ;
  var _:;
run;

data final;
  set d;
  time= strip(tranwrd(time,'_',''));
  label time= 'Time';
run;