补充说明：
因为我的数据idwrong比较大，idright很少，所以我不想改变现有idwrong的观测顺序
下面一个代码，改变了原来idwrong的观测顺序，有没有什么办法改进？
proc sql;
create table final as
select a.*,b.id as id2 from idwrong a left join idright b
on a.name=b.name and a.birth=b.birth;
quit;
data final;
set final;
if id2^=. then id=id2;
drop id2;
run;
data idwrong;
input id name $ birth;
cards;
1 张三 88
2 李四 87
4 周看 90
12 李四 85
;
data idright;
input id name $ birth;
cards;
3 李四 85
5 周看 90
;
run;
proc sql;
create table test as
select (case when b.id is missing then a.id else b.id end ) as id ,a.name,a.birth from
idwrong a left join idright b
on a.name=b.name and a.birth=b.birth
order by a.id;
quit;
data wanted;
if 0 then set idright;
*** define Hash object;
declare hash h(dataset:'idright');
h.definekey('name','birth');
h.definedata('id');
h.definedone();
do until(last);
set idwrong end=last;
_n_=h.find();
output;
end;
stop;
run;
pobel 发表于 2012-12-11 16:11
data wanted;
if 0 then set idright;
*** define Hash object;
谢谢你，但是我不知道为什么你写这么多
我删了一些看不太懂的，剩下这些，也是可以的啊？
data wanted;
if _n_=1 then do;
declare hash a(dataset:'idright');
a.definekey('name','birth');
a.definedata('id');
a.definedone();
end;
set idwrong;
_n_=a.find();
run;
扫码加好友，拉您进群
全部版块
我的主页
收藏
