在这个bar-line例子中，我认为两位高手的代码还存在一点点瑕疵。其中bobguy 的图形能实现柱状图左右分开，趋势线上下叠加，但是无法实现良率用线图，数量用柱图。（反过来实现的话，良率就必须放在右轴，而不是左轴）
而ziyenano 的图形是柱图和线图的点都是左右分开，而不是线图上下叠加。

上面代码是我认真学习帮助文档后的成绩，能完美实现要求的图形。不仅如此，也是定制作图的一般步骤。
第一步是恢复SAS默认模板。
第二步是定义一个公共模板，主要控制图形输出外观相关，例如用group=选项的时候，控制线条颜色。
第三步是定义一个画图模板，主要是定义生成什么图形，需要什么要素以及如何摆放。
第四步就是用上面定义好的模板画图。

但是，关于如何画趋势散点图的另外一个例子，目前我还没想到好办法，请各位继续指导，谢谢！



/*******************************************************************************************/
data test;
input Week $ UP_DOWN $ Yield Input;
datalines;
wk01        U        0.75        5452
wk01        D        0.67958        4519
wk02        U        0.74241        4313
wk02        D        0.83931        3765
wk03        D        0.84109        22843
wk05        D        0.79949        2339
wk06        U        0.62222        225
wk09        U        0.85874        2230
wk09        D        0.82832        6215
wk10        U        0.68742        7387
wk10        D        0.80633        8184
wk11        U        0.77253        12182
wk11        D        0.79991        10615
wk12        U        0.75884        13157
wk12        D        0.80153        4842
wk13        U        0.75761        3911
wk13        D        0.84413        1219
wk14        U        0.70016        2538
;
run;

/*******************************************************************************************/
%let _color=blue red green orange purple darkgrey
        lightvividblue lightvividred lightvividgreen darkyellow violet brown;
%let _marker=circle circle circle circle circle circle
        circle circle circle circle circle circle;
%let _line=1 1 1 1 1 1 1 1 1 1 1 1;

%macro colorList(_var=);
%do i=1 %to 12;
        "&_var&i"=%scan(&_color,&i)
%end;
%mend colorList;

%macro markerList(_var=);
%do i=1 %to 12;
        class &_var&i / markersymbol="%scan(&_marker,&i)" linestyle=%scan(&_line,&i);
%end;
%mend markerList;


/*******************************************************************************************/
options nolabel;
ods path sashelp.tmplmst(read) work.templat(update);

/*******************************************************************************************/
proc template;
        define style trend;
           parent=Styles.Default;
        class GraphFonts
                "Fonts used in graph styles" /
                'GraphDataFont'=("Arial",8pt)
                'GraphUnicodeFont'=("Arial",10pt)
                'GraphValueFont'=("Arial",12pt)
                'GraphLabelFont'=("Arial",12pt)
                'GraphAnnoFont'=("Arial",10pt)
                'GraphFootnoteFont'=("Arial",12pt)
                'GraphTitleFont'=("Arial",14pt,bold);
        class color_list
                "Colors used in the default style" /
                'bgA'=lightgray;
        class GraphBorderLines /
                linethickness=2px;
        class GraphColors /
                'ggrid'=lightgray
                'glabel'=black
                'gcdata'=blue
                'gwalls'=lightyellow
                %colorList(_var=gdata)
                %colorList(_var=gcdata);
        %markerList(_var=GraphData);
        end;
run;

/*******************************************************************************************/
proc template;
        define statgraph temp;
    begingraph;

    entrytitle 'Yield & Input By UP_DOWN';
    entryfootnote 'MIB Confidential, by Smoon team';

    layout overlay / yaxisopts=(griddisplay=on);
                barchart x=Week y=Input / group=UP_DOWN groupdisplay=cluster name="I"
                        yaxis=y2 fillattrs=(transparency=0.7) barwidth=1 clusterwidth=0.5;
        seriesplot x=Week y=Yield / group=UP_DOWN groupdisplay=overlay name="Y"
                        display=all lineattrs=(thickness=2) markerattrs=(size=12) break=true;
       
            layout gridded / columns=1 autoalign=(topleft topright);
                     entry halign=left textattrs=(color=blue) "UP weighted average = 75%";
                        entry halign=left textattrs=(color=red) "DN weighted average = 80%";
            endlayout;
    endlayout;

    layout globallegend / type=column;
        discretelegend "Y" / title="Yield(%)";
        discretelegend "I" / title="Input(Kpcs)";
    endLayout;

        endgraph;                                                         
        end;
run;

ods listing close;
ods html style=trend; *file='Yield.html' path='G:\SAS';
ods graphics on / reset=all width=9in height=4.5in;

proc sgrender data=test template=temp;
run;

ods html close;
ods listing;

貌似9.3才支持groupdisplay

template 是个好方法，
只是觉得语法烦了点，时间久了，就容易忘记，无奈啊

了解一下。

data ex;
input week $;
n=_n_;
num1=round(ranuni(0)*100+400);
num2=round(ranuni(0)*100+300);
cards;
wk01
wk01
wk01
wk02
wk02
wk02
;
run;
proc sql noprint;
select cat(n,'=',quote(compress(week))) into:format separated by ' ' from ex;
select count(1) into:count from ex;
quit;
proc format;
value axis  &format;
run;

proc sgplot data=ex;
scatter x=n y=num1/markerattrs=(symbol=diamondfilled color=blue size=10);
scatter x=n y=num2/markerattrs=(symbol=squarefilled color=red size=10);
xaxis values=(1 to &count by 1) tickvalueformat=axis.;
yaxis grid values=(0 to 600 by 100 ) ;
run;

ziyenano ，非常感谢！

根据你的指导，我修改了一下代码，效果图见图片。唯一的缺点就是不能每一周显示一个数字，而是一周有多个数字。

/*******************************************************************************************/
data test;
input Week EC $ Wafer $ Yield Input N;
datalines;
35        G        32CCB        0.75969        1781        1
35        I        25F2F        0.67953        4509        2
35        I        25F33        0.75215        2324        3
36        G        31C38        0.86103        1655        4
36        G        32527        0.84716        12850        5
36        G        3252C        0.83039        4251        6
36        G        32555        0.723        2769        7
36        G        3276C        0.83275        11390        8
36        G        32A8B        0.86513        3255        9
36        G        32A8F        0.8217        3466        10
36        G        32A90        0.77304        3798        11
36        G        32A91        0.78875        3413        12
36        G        32AA9        0.60618        3461        13
36        G        32AAC        0.8622        3106        14
36        G        32E5A        0.8231        831            15
36        G        32EE9        0.76768        891            16
36        G        32F3B        0.84331        919           17
36        H        32926        0.89561        820            18
36        I        2386E        0.72531        2547        19
36        I        3305C        0.63653        1593        20
36        I        33250        0.70183        1697        21
37        E        4F038        0.51043        1725        22
37        G        31A88        0.87808        812         23
37        G        31C38        0.81805        5320        24
37        G        31D2A        0.74186        1658        25
37        G        32555        0.72628        5060        26
37        G        325C6        0.86811        508         27
37        G        32B7F        0.77179        1560        28
37        G        32BCB        0.72298        1841        29
37        G        32E5A        0.91723        894         30
37        G        32EAC        0.87753        1780        31
37        G        32EB3        0.74673        1836        32
37        G        32EB6        0.84628        1763        33
37        G        32EE9        0.82094        1022        34
37        G        32F01        0.71214        1796        35
37        G        32F06        0.83528        856         36
37        G        32F18        0.76987        1673        37
37        G        32F3B        0.82124        772         38
37        H        32926        0.94324        4840        39

;
run;

proc sql noprint;
select cat(N,'=',quote(compress(put(week,2.)))) into:format separated by ' ' from test;
select count(1) into:count from nb.test;
quit;
proc format;
value axis  &format;
run;

/*******************************************************************************************/
proc template;
        define statgraph temp;
    begingraph /designwidth=9in designheight=6in;

    entrytitle 'Yield Trend By Wafer By EC';
    entryfootnote halign=center 'XXXX Confidential'
                              halign=right "XXXX";

    layout overlay / wallcolor=lightyellow
                yaxisopts=(label='Yield' offsetmin=0 offsetmax=0 griddisplay=on
                                        linearopts=(tickvalueformat=percent8.1
                                                        tickvaluesequence=(start=0 end=1 increment=0.05)
                                                        viewmin=0.5 viewmax=1))
                xaxisopts=(label='Week' griddisplay=on
                                        linearopts=(tickvalueformat=axis.
                                                                tickvaluesequence=(start=0 end=100 increment=2)));
        bubbleplot x=N y=Yield size=Input / group=EC
                        bubbleradiusmax=20 bubbleradiusmin=5 name='Y';

            layout gridded / columns=1 autoalign=(topright);
                     entry halign=left textattrs=(color=blue) "one point one wafer";
                        entry halign=left textattrs=(color=blue) "circle size represent qty";
            endlayout;
    endLayout;

    layout globallegend / type=column;
        discretelegend "Y" / title="EC:";
    endLayout;

        endgraph;                                                         
        end;
run;

/*******************************************************************************************/
ods listing close;
ods html style=default;
ods graphics on / reset=all;

proc sgrender data=test template=temp;
run;

ods html close;
ods listing;

学习

得向各位学习啊

好东西~~谢谢分享~~

对SAS作图也曾研究一段时间，时间久了就忘记！算是复习了~~

恩，SAS高版本才好用啊

效果不错，但是展示的效果还是没有Excel赞，不知道有高人知道怎么弄点立体效果什么的，看起来更炫

这么复杂，直接用excel搞定

个人还是喜欢stata的图，比较美观

个人还是喜欢stata的图，比较美观

看看 了解一下