%let libname=exist-libname;
%let Con=%str(date='23Jan2013'd);
%let newlib=work;

data _null;
   set sashelp.vtable;
   where libname=upcase("&libname");
   call execute("data &newlib.."||strip(memname)||";");
   call execute("   set &libname.."||strip(memname)||";");
   call execute("   where &con;");
   call execute("run;");
run;
   

libname mylib 'C:\data';
%let newlib=work;

proc sql noprint;
        select memname into :dataname
        from sashelp.vtable
        where libname='MYLIB';
quit;

data &newlib..&dataname.;
        set mylib.&dataname.(where=(date='23JAN2013'd));
run;

这个可以修改吗？
dataname只能显示第一个数据集的名字，而且最下面的data步只能对一个数据集起作用。。
不知咋改

因为PROC SQL那一步只是把第一个数据集的名字存到了宏变量dataname中。

如果用这种方法应该需要用到宏了。

那要改的话怎么改呢？

libname mylib 'C:\data';
%let newlib=work;

%macro test(oldlib=mylib,newlib=work,con=%str(date='23JAN2013'd));
        proc sql noprint;
                select memname into :dataname1-:dataname9999
                from sashelp.vtable
                where libname=upcase("&oldlib");
        quit;

        %do i=1 %to &sqlobs;
        data &newlib..&&dataname&i;
                set &oldlib..&&dataname&i.(where=(&con));
        run;
        %end;
%mend;

%test()