这个可能最快。。。

您好，非常感谢您的回答！
有两个小的问题
1 如果要是id中不仅是数字还有字母，而且id数量众多。应该如何解决？
2 本身样本量大，超百万行，全部读入hash可能内存不够。有没有其他办法或者思路呢？
非常感谢！论坛币我一定会给您的！

i提供点原始数据看看？
百万行放在内存中应该没问题吧，变量很多吗？

楼主，做两次转置即可。程序如下：

data t1;
input id date quan price;
datalines;
1 1 10 2
1 2 9 2
2 1 8 2
2 2 7 2
2 3 6 2
3 2 5 2
;
run;

proc transpose data=t1 out=t2(drop=_name_) prefix=date;
by id;
id date;
var quan price;
run;

proc transpose data=t2 out=t3;
by id;
var date1 date2 date3;
run;

data final;
set t3;
length date 8.;
_name_=compress(_name_,'date');
drop _name_;
rename col1=quan col2=price;
run;

我来补充一下下。
data t1;
       input id $ date quan price;
datalines;
1        1        10        2
1        2        9        2
2        1        8        2
2        2        7        2
2        3        6        2
3        2        5        2
mm       5        4        2
;
run;
proc sort data=t1(keep=id) out=t2 nodupkey;by id ;run;
data t2;
    set t2;
        do date=1 to 10;
            call missing(quan,price);
                output;
        end;
run;      
data t3;
update  t2 t1;
by id date;
run;

Here is a simple data step solution in a simple logic. Assume data is sorted by id date and the variable date is a sas numerical variable.

k=1;  <---- 1 is lower bound
do s=k to 3;  <-- 3 is upper bound.

data t1;
    input id date quan price;
datalines;
1        1        10        2
1        2        9        2
2        1        8        2
2        2        7        2
2        3        6        2
3        2        5        2
;
run;

  data t1;
    retain k;
    set t1;
        by id;
        if first.id then k=1;
        do s=k to date-1;
          quan_new=.; price_new=.;
          output;
        end;
        quan_new=quan ; price_new=price;
        output;
        k=date+1;
        if last.id then do;
          do s=k to 3;
             quan_new=.; price_new=.;
             output;
           end;
        end;
        drop date    quan    price k;
        rename s=date;
  
  run;

  proc print;run;

/*  Here is another way, it use do-loop and sort           */
/*  Try the following code to see if it is faster                 */
/*  than merge and hash table for this special problem   */


data test;                 /* create the sample data set */  
   do ID = 1000001 to 1100000;
      do date = ceil(ranuni(123)*10) to ceil(ranuni(123)*10);
         quan = ceil(ranuni(123)*100);
        price = round(ranuni(123)*100,0.01);
        output;
      end;
   end;
run;

proc sort data=test;       /* the sorting is required if real data was not sorted */
by id date;        run;

data test1;
  set test;
  by id;
    if first.id then do;   output;
      if date ^= 1 then do;
         do i =  date-1 to 1 by -1;
           date = i;   call missing(quan, price);
           output;     /* fill the missing date             */  
         end;          /* end of loop for fill missing date */
      end;             /* end of loop for data^=1           */  
    end;               /* end of loop for first.id          */   
   if not last.ID then output;
   if last.ID then do;   output;
      if date ^=10 then do;
         do i = date+1 to 10;
           date = i;  call missing(quan, price); output;
         end;
      end;
    end;
drop i;
run;

proc sort data=test1 out = result nodupkey;
by id date; run;  

proc print data=result(obs=100); title 'result'; run;

嗯，学习了。效率应该可以。。。

排序过程可能会耗去很多时间啊。。。。maybe。。。。

Yes, you are right. It must be taken into account.
Sometime sorting use more time than computing.
However, for this case the hash table may be too large.

黄泉下阴气太重，出来凑个热闹，不敢跟大家比EFFICIENCY

Your excellent SAS skills should have inhibited the dummy of id=2,but be careful even now!

学习了。各位大神。

下面这个就不限ID的变量类型了！

很感谢您的思路和回答！！

很感谢您的思路和回答！！

这么效率确实有点低。。原数据有斤千万条。。而且我的小破电脑还不咋行~！不过非常感谢您的回答！

太感谢您了！！

您好！我现在没有很理解邓贵大大神的解答方案，您评价说可能是最好的解决方案。可否简要给说说为什么呢？

太感谢您了！！hash用的如此纯熟！