%let path=c:\temp;  
%macro showstyle(style);
ods html path="&path"(url=none) file="&style..html"
    contents=temp(notop nobot) frame="frame.html" style=&style;
ods proclabel "Style name";
proc print data=sashelp.class contents="Styles.&style";
run;
ods html close;
%mend;
ods path work.templat(update) sashelp.tmplmst(read);
filename temp "&path\contents.html" mod;
ods html path="&path"(url=none) contents=temp(nobot);
ods html exclude stats;
ods output stats=styles(where=(type ne "Dir"));
proc template;
   list styles;
run;
proc sort data=styles;
   by path;
run;
data one;
   set styles;
   by path;
   if first.path then
      call execute('%showstyle('||path||')');
run;
data _null_;
   file temp;
   put "</body>";
   put "</html>";
run;
ods path reset;

这里有几个地方值得学习
1.PROC TEMPLATE列出了所有SAS附带的输出结果展示的样式
2.用CALL EXECUTE调用宏程序。
3.宏程序里面的主要的是ODS参数的设置，以及最后对ODS PATH RESET。

/*用宏程序按照数据集中的BY分组变量来创建不同的数据集*/
data test;
  input color $ num;
datalines;
blue 1
blue 2
blue 3
green 4
green 5
red 6
red 7
red 8
;
/* 创建一个新的宏变量VARn*/
/* 创建一个新变量flag，这个用来记录每一组，按照BY分了三组，每一组里面的FLAG是一样的，但是不同的COLOR组是不一样，递增的关系
例如1,2,3然后根据FLAG创建宏变量
VAR1 VAR2 VAR3.....*/
data we;
  set test end=eof;
  by color;
  if first.color then do;
   flag+1;
   call symput('var'||put(flag,8. -L),color);
  end;
  /* 最后一个观测时，将此时的FLAG创建并赋值给宏变量TOT，也就是TOT这个宏变量记录了分组数 */                              
  if eof then call symput('tot',put(flag,8. -L));
run;
/* 动态创建数据集，根据宏变量根据IF THEN语句判断输出到不同的数据集中*/
                                       
%macro groups(dsn,byvar);
  data %do i=1 %to &tot; /*如果TOT=3的话，那么就是等价于&var1,&var2,&var3*/
         &&var&i
       %end;;
    set &dsn;
      %do i=1 %to &tot;
        if &byvar="&&var&i" then output &&var&i;
      %end;
  run;
%mend groups;
%groups(test,color)
proc print data=blue;
  title 'Blue';
run;
proc print data=green;
  title 'Green';
run;
proc print data=red;
  title 'Red';
run;




这里有一个技巧就是
call symput('var'||put(flag,8. -L),color);
这句是创建的一个系列的宏变量，而不是一个宏变量
可以对照symget来看看

也可以用call execute();

data test;
  input color $ num;
datalines;
blue 1
blue 2
blue 3
green 4
green 5
red 6
red 7
red 8
;

proc sql;
    select distinct color into : dslist separated by " "
          from test;
run;

data _null_;
     if _n_=1 then call execute("data &dslist;  set test;");
         set test end=last;
         by color;
         if first.color then  call execute("if color="||quote(strip(color))||" then output "||color||";");
         if last then call execute("run;");
run;

data test;
  input color $ num;
datalines;
blue 1
blue 2
blue 3
green 4
green 5
red 6
red 7
red 8
;
data blue green red;
set test;
if color='blue' then output blue;
if color='green' then  output green;
if color='red' then output red;
run;

data one;
  input var1 $ var2;
datalines;
A 10
B 22
C 5
D 41
E 33
;
run;


data two;
   set one;
   call missing(next_var2); /*set next_var2 to missing because variable value are automatically retained*/
   if not last then do;   
       set one(firstobs=2 keep=var2 rename=(var2=next_var2)) end=last; /*reread dataset one from the second observation*/
       dif=var2-next_var2;
        end;
run;

不好意思 不懂。。。。。。。。。。。。。

proc sql outobs=20;
title ’Job Groups with Average Salary’;
title2 ’> Company Average’;
select jobcode,
avg(salary) as AvgSalary format=dollar11.2,
count(*) as Count
from sasuser.payrollmaster
group by jobcode
having avg(salary) >
(select avg(salary)
from sasuser.payrollmaster)
order by avgsalary desc;

这个里面主要是注意一点：
就是HAVING语句中的AVG(salary)比较是全部数据中的薪水的平均值，而AVG(SALARY)是按照分组计算出来的薪水的平均值，这里将select avg(salary)
from sasuser.payrollmaster的结果做比较的对象。

楼主的代码一个data步输出到多个datasets，原表仅遍历一次
pobel的代码可能需要多个data步遍历原表多次来完成，效率上可能略逊一筹
楼上的方法本质和楼主的方法一致，只是当分组不那么明显的时候，楼主的方法更具一般性

一个小建议，使用if-else语句可能效率较之if-if语句更好。

  proc sql;
15       select distinct color into : dslist separated by " "
16             from test;
17   run;
NOTE: PROC SQL statements are executed immediately; The RUN statement has no effect.
18
NOTE: PROCEDURE SQL used (Total process time):
      real time           0.36 seconds
      cpu time            0.12 seconds

19   data _null_;
20        if _n_=1 then call execute("data &dslist;  set test;");
21            set test end=last;
22            by color;
23            if first.color then  call execute("if color="||quote(strip(color))||" then output "||color||";");
24            if last then call execute("run;");
25   run;
NOTE: There were 8 observations read from the data set WORK.TEST.
NOTE: DATA statement used (Total process time):
      real time           0.06 seconds
      cpu time            0.01 seconds

NOTE: CALL EXECUTE generated line.
1   + data blue green red;  set test;
2   + if color="blue" then output blue    ;
3   + if color="green" then output green   ;
4   + if color="red" then output red     ;
5   + run;
NOTE: There were 8 observations read from the data set WORK.TEST.
NOTE: The data set WORK.BLUE has 3 observations and 2 variables.
NOTE: The data set WORK.GREEN has 2 observations and 2 variables.
NOTE: The data set WORK.RED has 3 observations and 2 variables.
NOTE: DATA statement used (Total process time):
      real time           0.01 seconds
      cpu time            0.01 seconds



遍历三次就可以了，第一次产生宏变量，第二次产生call execute的代码，第三次输出到不同的数据集。
楼主的方法是两次遍历，第一次产生宏变量，第二次分组输出到不同数据集。

If ... then ...; else if... then ...; 最基本的提高效率的方法，受教了。

你起得好早哦
兄弟

5# pobel
对的，你的输出也是遍历全表一次，我看错代码了......，和crackman的一样的......

[biggrin]

[biggrin]

内嵌查询，看起来很完美，但实际上应用起来非常困惑，实在慢的不行，特别当你运行千万数量级的数据的时候！

proc format;                           
   picture mypct low-high='000,009%';   
run;
proc tabulate data=sashelp.class;
   class name sex;
   var weight height;
   table name, sex*(weight height)*(pctsum*f=mypct.);
run;

当我们需要TABLE里面带有我们需要的‘%’的时候，可以用FORMAT里面定义的格式

proc format;
   value color low-2='green'
                 3-5='blue'
              6-high='orange';
run;

proc template;
   define crosstabs Base.Freq.CrossTabFreqs;
      cell_style={foreground=color.};
      row_total_style={foreground=color.};
      col_total_style={foreground=color.};
      grand_total_style={foreground=color.};
   end;
run;

ods listing close;
ods html file='body.html';

proc freq data=sashelp.class;
   tables age*sex / norow nocol nopercent;
run;

ods html close;
ods listing;

这里主要是通过FORMAT来制定TEMPLATE的输出格式和颜色

options minoperator mlogic;
%macro test(value)/mindelimiter=',';

%if &value in 1,2,3,4,5,6 %then
  %put Value found within list.;
%else %put Value not in list.;

%mend;

%test(3)
上面的程序等价下面的程序
%macro test(value);
  %if &value=1 or &value=2 or &value=3 or &value=4 or
  &value=5 or &value=6 %then %put Value found within list.;
  %else %put Value not in list.;
%mend;
%test(3)
但是明显简洁多了，因为第一个程序用 IN这个运算符
不过要用IN运算付有效，必须在OPTIONS设置一个参数，就是minoperator。同时注意个参数的学习，就是mlogic，这个可以再LOG中显示IF THEN的运行结果以及机制的提示。
这点是SAS9.2里面的新的一个特点

1# crackman
斑竹辛苦，不顶不行！

data one;
  input x;
datalines;
1
2
;


%let dsid=%sysfunc(open(one));
%let num=%sysfunc(attrn(&dsid,nlobs));
%let rc=%sysfunc(close(&dsid));

%put There are &num observations in dataset one.;
在这里，学习的几点：
1.在宏中使用函数，除了本身有的宏函数之外，一般都要用%sysfunc
2.在DATA步，我们首先是打开数据集，然后获得该数据集的属性值，观测数、变量数、记录的长度、INDEX等等，详细可以看看函数ATTRN的用法
3.一定要关闭打开的数据集，释放内存空间。

这个程序很值得保留。

1# crackman
斑竹之SAS功力非我等所能企及，偶等佩服！

经常要用到proc tabulat，学习了！再顺便请教一问题，tabulate里行维和列维的顺序如何自定义，如上面的name变量中，有“张三”、“李四”、“王五”等等，我要自定义一个排序怎么做。如“李四”排第一，“张三”拍第二。我在其他应用程序中，可以方便的自定义这个顺序，不知道在sas能否做到？

sort一下 然后By你需要的排序变量 就完了

斑竹，对于数据集，查看观测的个数有多种方法，这个是不是有点　牛刀杀鸡呀?！

data color;                                                                                                                          
   input Region Eyes $ Hair $ Count @@;                                                                                             
   label Eyes  ='Eye Color'                                                                                                      
         Hair  ='Hair Color'                                                                                                      
         Region='Geographic Region';                                                                                             
   datalines;                                                                                                                     
   1 blue  fair   23  1 blue  red     7  1 blue  medium 24                                                                              
   1 blue  dark   11  1 green fair   19  1 green red     7                                                                              
   1 green medium 18  1 green dark   14  1 brown fair   34                                                                              
   1 brown red     5  1 brown medium 41  1 brown dark   40                                                                              
   1 brown black   3  2 blue  fair   46  2 blue  red    21                                                                              
   2 blue  medium 44  2 blue  dark   40  2 blue  black   6                                                                              
   2 green fair   50  2 green red    31  2 green medium 37                                                                              
   2 green dark   23  2 brown fair   56  2 brown red    42                                                                              
   2 brown medium 53  2 brown dark   54  2 brown black  13                                                                              
   ;
run;                                                                                                                                 
                                                                                                                                       
proc freq data=color nlevels;                                                                                                         
   tables region eyes hair ;                                                                                                               
run;                                                                                                                                    
        

看看见过就知道了：
                                                         SAS 系统              
                                                      FREQ PROCEDURE
                                                       变量水平数
                                         变量      标签                     水平
                                         ---------------------------------------
                                         Region    Geographic Region           2
                                         Eyes      Eye Color                   3
                                         Hair      Hair Color                  5

                                                    Geographic Region
                                                                      累积       累积
                                   Region      频数      百分比       频数      百分比
                                   ---------------------------------------------------
                                        1          13     48.15           13     48.15
                                        2          14     51.85           27    100.00

                                                        Eye Color
                                                                      累积       累积
                                    Eyes       频数      百分比       频数      百分比
                                    --------------------------------------------------
                                    blue            9     33.33            9     33.33
                                    brown          10     37.04           19     70.37
                                    green           8     29.63           27    100.00

                                                       Hair Color
                                                                      累积       累积
                                   Hair        频数      百分比       频数      百分比
                                   ---------------------------------------------------
                                   black            3     11.11            3     11.11
                                   dark             6     22.22            9     33.33
                                   fair             6     22.22           15     55.56
                                   medium           6     22.22           21     77.78
                                   red              6     22.22           27    100.00