var y c i g n k w rk tau_k tau_w tau_c f_tau_w f_tau_k f_tau_c;
varexo epsilon_g epsilon_f_tau_w epsilon_f_tau_k epsilon_f_tau_c;
parameters Y C I G N K W RK TAU_K TAU_W TAU_C R;
parameters alpha beta phi_n delta_k C_div_Y;
N        =1/3;
alpha    =0.54;
beta     =0.9804;
TAU_K    =0.3;
TAU_W    =0.1;
TAU_C    =0.15;
delta_k  =0.1;
C_div_Y  =0.415;  
phi_n    =(1-N)/N*(1-alpha)/0.417;
R        =1/beta;
RK       =(R-1+delta_k)/(1-TAU_K);        
Y        =((alpha*(1-TAU_K)/(R-1+delta_k))^alpha*N^(1-alpha))^(1/(1-alpha));//用N和参数解出Y
W        =(1-alpha)*Y/N;//根据不同的N的取值，可以得到不同的W值
C        =0.415*Y;
I        =delta_k*alpha*(1-TAU_K)/(R-1+delta_k)*Y;
G        =Y-C-I;
K        =alpha*(1-TAU_K)/(R-1+delta_k)*Y;
parameters phi_tau_w_g phi_tau_k_g phi_tau_c_g rho_g rho_f_tau_w rho_f_tau_c rho_f_tau_k;
phi_tau_w_g=1;
phi_tau_k_g=1;
phi_tau_c_g=1;
rho_g      =0.8;
rho_f_tau_w=0.5;
rho_f_tau_c=0.5;
rho_f_tau_k=0.5;
model;  //模型
//一、居民部门
//1.居民跨期消费欧拉方程
c(+1)-c+TAU_C/(1+TAU_C)*(tau_c(+1)-tau_c)=beta*(1-TAU_K)*RK*(-TAU_K/(1-TAU_K)*tau_k(+1)+rk(+1));   
//2.居民选择最优劳动时，消费、劳动与工资的关系
c+TAU_C/(1+TAU_C)*tau_c-N/(1-N)*n=-TAU_W/(1-TAU_W)*tau_w+w;
//二、厂商部门
//3.生产函数
y = alpha*k(-1)+(1-alpha)*n;
//4.资本形成方程
k=(1-delta_k)*k(-1)+delta_k*i;
//5.资本价格
rk=(alpha-1)*k(-1)+(1-alpha)*n;
//6.劳动价格
w=alpha*k(-1)-alpha*n;
//三、ZF部门
//7.ZF预算约束
G*g=TAU_C*C*(tau_c+c)+TAU_K*RK*K*(tau_k+rk+k(-1))+TAU_W*W*N*(tau_w+w+n);
//8.ZF购买
g=rho_g*g(-1)+epsilon_g;
//9&10.劳动税税率规则
tau_w=phi_tau_w_g*g+f_tau_w;
f_tau_w=rho_f_tau_w*f_tau_w(-1)-epsilon_f_tau_w;
//11&12.资本税税率规则
tau_k=phi_tau_k_g*g+f_tau_k;
f_tau_k=rho_f_tau_k*f_tau_k(-1)-epsilon_f_tau_k;
//13&14消费税税率规则
tau_c=phi_tau_c_g*g+f_tau_c;
f_tau_c=rho_f_tau_c*f_tau_c(-1)-epsilon_f_tau_c;
//四、市场出清条件
//15.产品市场出清
Y*y=C*c+I*i+G*g;
end;
initval;
tau_c  =0;
tau_k  =0;
tau_w  =0;
c      =0;
n      =0;
w      =0;
rk     =0;
y      =0;
k      =0;
i      =0;
g      =0;
f_tau_w=0;
f_tau_k=0;
f_tau_c=0;
end;
steady;
//resid(1);
check;
shocks;
//var epsilon_g;
//stderr 0.01;
var epsilon_f_tau_w;
stderr 0.01;
var epsilon_f_tau_k;
stderr 0.01;
//var epsilon_f_tau_c;
//stderr 0.01;
end;
stoch_simul(irf=20);

这个是不含有债券和利率的版本

1，市场出清是应该考虑的。

2，市场出清，特别是全面的市场出清，在现实当中是不存在的，不会发生的。

比较类似于惯性定律，


假若没有任何阻力等等，物体会匀速运动下去。

但是，这种无摩擦力无阻力的境界，现实当中不存在。

1.居民的约束肯定是不需要放在方程系统的，因为家庭的FOC已经包含了他。
2.ZF部门和总的预算约束都应该写上，但是发现少了一个方程，因为债券只出现在ZF部门。不知道怎么解决？