data test;
input num @@;
cards;
1 2 3 . . . 4 5 6 . 7 8 . . . . 9 10
;

data wanted;
  set test;
  retain _num;
  if num ne . then _num=num;
  else num=_num;
  drop _num;
run;

多谢啦^_^
但这个做出来的是把每一个空格处都填上上一条的值，有没有什么办法可以把每一个空格处都填上离其最近的非空格值呢，比如，8，blank，blank，blank，blank，blank，9，10得到8，8，8，8，9，9，9，10呢？
如果blank是偶数个，那么正好一半blank同前，一半blank同后；
如果blank是奇数个，那么最中间的blank同前同后均可。
太感谢啦~~

sorry，开始没看清楚你的例子；
试试这个，如果blank是奇数个，在test2那一步，中间的同前用ceil函数，同后用int函数：

data test;
input num @@;
cards;
1 2 3 . . . . 4 5 6 . 7 8 . . . . . 9 10
;

data test1;
  set test;
  obs=_n_;
  lagnum=lag(num);
  if nmiss(num,lagnum)=1 then grp+1;
  if num ne . then n=0;
  else n+1;
  drop lagnum;
run;

proc sql;
create table test2 as
select *, ceil(max(n)/2) as sn
from test1
group by grp
order by obs;
quit;

data test3;
set test2;
retain _num;
if num ne . then _num=num;
else if num=. and n<=sn then num=_num;
drop _num;
run;

proc sort data=test3;
by descending obs;
run;

data test4;
set test3;
retain _num;
if num ne . then _num=num;
else num=_num;
drop _num;
run;

proc sort data=test4(keep=num obs) out=wanted;
by obs;
run;

哇，太感谢了多谢大神啦^_^

哇，太感谢了多谢大神啦^_^