看我的5楼哈，双版主出动......

这个代码在N取很大值(比如1000)就会有点问题,SAS要产生1000列,这可能不是楼主希望的.我一开始也想到用MAX函数,但是无法解决列很多的问题.

谢谢了，非常感谢！！

8# nkwilling
仅仅是PDV有n列，输出的还是移动窗口的最大值和最大值条数距今差

4# nkwilling
很厉害，point玩得如此熟练

5# soporaeternus
写的很不错
值得学习

4# nkwilling
为了更多的初学者能读懂牛人的代码，我来翻译一下，就如soporaeternus 哥们说的，第三类人，翻译人员
data a; /*创建数据集A*/
input x @@;
cards;
2 5 6 9 8 2 6 5 4 7 9 5 6 7
;
run;
data aa; /*创建数据集AA，变量换名为X1*/
set a;
rename x=x1;
run;
data b;
DO row=5 TO 14; /*外循环，外循环每执行一次，内循环执行5次*/
set a point=row; /*复制指定的观测，ROW=5时说复制数据集A中的第五条观测对象的X的变量值*/
   do col=row-4 to row; /*内循环，同样建立一个指针变量COL*/
      set aa point=col; /*从指定的变量COL的值处取AA中指定的观测对象的X1的变量值，例如当COL=1的时候，就复制AA数据集中第一个条观测*/
          retain xxx xx;/*初始化变量XXX XX*/
          xx=max(x1,x);/*当第一次内循环时，也就是COL=1时，从AA取出的X1的第一条观测值和外循环取出的X的第五条观测值进行比较大小，并将较大值赋值给XX*/
          xxx=max(xxx,xx); /*比较XXX XX,将值大者赋值给XXX*/
          put xx= @; /*在LOG输出XX. XXX X1 X*/
          put xxx= @;
          put x1= @;
          put x=;
   end; /*结束一次内循环*/
output;
xxx=0; /*XXX值清0*/
put xxx=; /*输出XXX*/
END; /*结束外循环*/
stop; /*结束循环程序*/
keep xxx; /*结果数据集保留XXX变量*/
run;
大家如何还是不能理解可以这样等价来看：
xx=8 xxx=8 x1=2 x=8  row=5 col=1
xx=8 xxx=8 x1=5 x=8  row=5 col=2
xx=8 xxx=8 x1=6 x=8  row=5 col=3
xx=9 xxx=9 x1=9 x=8  row=5 col=4
xx=8 xxx=9 x1=8 x=8  row=5 col=5
xxx=0
xx=5 xxx=5 x1=5 x=2  row=6 col=1
xx=6 xxx=6 x1=6 x=2 row=6col=2
xx=9 xxx=9 x1=9 x=2 row=6 col=3
xx=8 xxx=9 x1=8 x=2 row=6 col=4
xx=2 xxx=9 x1=2 x=2 row=6 col=5
xxx=0
xx=6 xxx=6 x1=6 x=6
xx=9 xxx=9 x1=9 x=6
xx=8 xxx=9 x1=8 x=6
xx=6 xxx=9 x1=2 x=6
xx=6 xxx=9 x1=6 x=6
xxx=0
xx=9 xxx=9 x1=9 x=5
xx=8 xxx=9 x1=8 x=5
xx=5 xxx=9 x1=2 x=5
xx=6 xxx=9 x1=6 x=5
xx=5 xxx=9 x1=5 x=5
xxx=0
xx=8 xxx=8 x1=8 x=4
xx=4 xxx=8 x1=2 x=4
xx=6 xxx=8 x1=6 x=4
xx=5 xxx=8 x1=5 x=4
xx=4 xxx=8 x1=4 x=4
xxx=0
xx=7 xxx=7 x1=2 x=7
xx=7 xxx=7 x1=6 x=7
xx=7 xxx=7 x1=5 x=7
xx=7 xxx=7 x1=4 x=7
xx=7 xxx=7 x1=7 x=7
xxx=0
xx=9 xxx=9 x1=6 x=9
xx=9 xxx=9 x1=5 x=9
xx=9 xxx=9 x1=4 x=9
xx=9 xxx=9 x1=7 x=9
xx=9 xxx=9 x1=9 x=9
xxx=0
xx=5 xxx=5 x1=5 x=5
xx=5 xxx=5 x1=4 x=5
xx=7 xxx=7 x1=7 x=5
xx=9 xxx=9 x1=9 x=5
xx=5 xxx=9 x1=5 x=5
xxx=0
xx=6 xxx=6 x1=4 x=6
xx=7 xxx=7 x1=7 x=6
xx=9 xxx=9 x1=9 x=6
xx=6 xxx=9 x1=5 x=6
xx=6 xxx=9 x1=6 x=6
xxx=0
xx=7 xxx=7 x1=7 x=7
xx=9 xxx=9 x1=9 x=7
xx=7 xxx=9 x1=5 x=7
xx=7 xxx=9 x1=6 x=7
xx=7 xxx=9 x1=7 x=7
xxx=0

5# soporaeternus
这个哥们写的程序很有其他程序代码的风格，很不错，确实很值得学习

• %MACRO T(n);
• data b;
•         retain t0-t%eval(&n-1) 0;/*初始化变量t0-t4,假设n=5*/
•         set a;
•        %do i=%eval(&n-1) %to 1 %by -1;
  
•                 t&i=t%eval(&i-1);
  
•         %end; /*这点我很欣赏，有点类似于一个队列一样，当SET 复制指针从1---14，每读取一个，然后看看T0-T4的变化，像一个队列，不断的进入从最低端往上冒*/
•         t0=x;
•         max=max(of t0-t%eval(&n-1));
•         dis=max(0*((t0-max)=0)%do i=1 %to %eval(&n-1) %by 1;,&i*((t&i-max)=0)%end;);  /*这一句有点难理解，用了一个宏循环来重复实现MAX函数的后一个比较数，这点类似在其他编程里面，像用一个函数得出一个返回值，用这个返回值作为MAX函数的另外一个比较数字，这里的宏就是实现了这样的一个功能，不过注意中间的逗号不能丢，因为宏这个时候repeat的是一个语句（，1*(（t1-max）=0） 2*((t2-max)=0)........)*/
• /*        dis=min(0*((t0-max)=0)%do i=1 %to %eval(&n-1) %by 1;,&i*((t&i-max)=0)%end;);*/
•         keep x max dis;
• run;
• %MEND T;
• %T(5);

擦，来晚了完事了 扔块砖走人~~
data raw;
input a@@;
cards;
2 5 6 9 8 2 6 5 4 7 9 5 6 7
;run;


%macro i(n);
data b;
set raw;
by a notsorted;
array t t1-t&n;
t0=a;
%do i=1 %to &n;
t&i=lag&i(a);
b=max(of t0-t%eval(&n-1));
%end;
keep a b;
run;
data final;
set b;
by b notsorted;
if first.b then c=0;
else c+1;
if first.b then c=b-a;
run;
%mend ;
%i(5);

有意思，crackman唱完红脸，我来唱白脸，呵呵。
4# nkwilling
第一个就是point的使用有对数据集的限制，连接到关系型数据库的表大多不能使用point，至少到现在我还没遇到哪个数据库是不被限制的，原因就是log中的error，非随机访问。
第二个就是效率问题：海量数据较大情况下，虽然rename和copy可以不用data step，而用proc datasets来提高一点点效率，但是新建表临时表的方式，会使海量数据对存储形成挑战，其次嵌套循环的计算量也不少。

5# soporaeternus
个人认为更值得探讨的是，N个临时变量是否可以采用array _temporary_，这样array变量并不存储在pdv而是直接存储在memory里（虽然pdv也是存储在memory里），但对于N较大情况下，drop的计算量也可以减少一些，还有一点好处是 _temporary_自动retain的。

呵呵，鸡蛋里挑骨头，欢迎拍砖。

16# yatming
恩，关键是array我不是很熟.......，不到万不得已坚决不用array......
PDV变量很多的时候，可能在变量的keep或drop flag的处理上浪费资源，这点array 到temp更好，因为它默认不输出。

DATA x;
INPUT A@@;
DATALINES;
2 5 6 9 8 2 6 5 4 7 9 5 6 7
;
DATA y;
SET x;
ARRAY A_{5} _TEMPORARY_; /*建立临时数据A_*/
N = MOD(_N_, 5);  /*用自动变量—_n_与5的相除的余数赋值给变量N*/
IF  NOT N THEN N =5; /*这里关键是NOT N=TRUE的意义，因为当_N_与5的余数为0时，就是 NOT 0 即为1也就是TRUE*/
A_[N] = A; /*将从X读取每一个X变量赋值给临时数组A_*/
B = MAX(OF A_

); /*从临时数组A_中取最大值，这里仔细研究，精彩之处也就是此处*/
put a_[1]=  a_[2]=  a_[3]=  a_[4]=  a_[5]=  B=;  /*为了理解程序，我加的一行，网友好好看看，其实就是相同N时，a_进行替换*/
DO I = 1 TO 5;
  IF B = A_[I] THEN DO; /*判断最大值时N对应的值*/
   C = IFN(N-I <0, N-I+5, N-I);  /*相当于if n-I<0 then c=n-I+5;else c=N-I;*/
  LEAVE;
  END;
END;
IF _N_ <5 THEN CALL MISSING(B, C); /*相当于IF _N_<5 then b=c=.;*/
RUN;

5# soporaeternus

您的程序正好，太感谢您了！！

4# nkwilling

谢谢，学习到一点point的用法了！哈哈

很精彩 学习了
这也是我天天来的原因 呵呵

谁有兴趣把soporaeternus的代码用临时数组实现吧,Jingju11和我的代码可读性都没有soporaeternus的代码强.如果soporaeternus代码用临时数组实现,将应该是最好的答案.有兴趣的也可以同时比较我们三个人的代码效率,用100万行*100列测试.谢谢!

Here is one to handle it all in memory. It should be fast enough.

data tmp;
do i = 1 to 100000;
   x=ceil(ranuni(12345)*10000) ;
   output;
end;
drop i;
run;

%macro max(start,var,loopvar);
    %let i=0;
max( %do k=&start %to 1 %by -1;
       %let i=%eval(&i+1);
      %if &k ne 1 %then  &var( &loopvar-&start+&i ),  ;
      %else   &var( &loopvar-&start+&i )                 ;
      %end ;
      )
%mend;

*data _null_;

%let start=10;

data tmp2;
   array _x_(1000000)  _temporary_;
   do until (end);
      set tmp end=end nobs=nobs;
           i+1;
           _x_(i) = x;
    end;
    do i=&start     to nobs;
        b=%max(&start,_x_,i);
        if i=&start then do ;
            c=1;
            max_1=b;
        end;
        else if b ne max_1 then do;
              c=0;
              max_1=b;
        end;
        else c+1;
        output ;
        *put b= c=;
    end;
run;
proc print data= tmp(obs=100);
run;
proc print data= tmp2(obs=100);
run;

这个论坛上SAS让我佩服的几个全都来了

不得不说 这帖子里回复的很精彩

每种程序都体现在不同的方面，值得我好好学习啊！

借花献佛
data a;
input x @@;
cards;
2 5 6 9 8 2 6 5 4 7 9 5 6 7
;
%let lag_n=5;
data b(drop=pre arr:);
array arr[0:%eval(&lag_n-1)];
   pre=0;
   do _n_=1 by 1 until(last);
      set a end=last;
      arr[pre]=x;
      pre=mod(pre+1,&lag_n);
      if _n_>=&lag_n then do;
         max=max(of arr[*]);
         end;
      output;
   end;
run;

data a;
   do k=1 to 100;
         x=ceil(10*ranuni(123));
         output;
   end;
run;

data b;
   set a;
   rename x=y
          k=k1;
run;
%let lag_n=5;

data temp_data(drop=k1 y rc);
    if _n_=1 then
        do;
if 0 then set b;
           declare hash h(dataset:'b');
          h.definekey ('k1');
          h.definedata(all:'yes');
          h.definedone();
           declare hiter p_hiter('h');
        end;
   set a;
   length temp $100;
   id=0;       
    rc=p_hiter.first();
    do while(rc eq 0);
        if  0<=k-k1<&lag_n then
            do;   
            if id=0 then temp=cat(y);
               else temp=catx(',',temp,y);
           id+1;
            end;
        rc=p_hiter.next();
    end;
run;

%macro max_dy;
   %let dsid=%sysfunc(open(temp_data));
    %let nobs=%sysfunc(attrn(&dsid,nobs));
    %syscall set(dsid);
    %do i=1 %to &nobs;
       %let rc=%sysfunc(fetchobs(&dsid,&i));
      k=&k;
      x=&x;
      %if &id=&lag_n %then %do;
           max_x=max(&temp);
         %end;
        output;
   %end;
   %let dsid=%sysfunc(close(&dsid));
%mend;

data final;
   %max_dy;
run;

proc import out=a
datafile="C:\Documents and Settings\boonepks\桌面\CU指数"
dbms=excel replace;
sheet="cu";
run;
proc import out=c
datafile="C:\Documents and Settings\boonepks\桌面\CU"
dbms=excel replace;
sheet="cu";
run;
data c;
set c;
rename date=date1 time=time1;
run;
%macro t(n,m,t);
%do a=1 %to &n;
%do b=2 %to &m;
%do c=2 %to &t;
data a;
set a;
tr=max(max((high-low),abs(lag(close)-high)),abs(lag(close)-low));
retain atr1 0;
atr1=atr1+tr;
run;
data a;
set a;
atr2=lag&a(atr1);
atr=1/&a*(atr1-atr2);
data b;
retain t0-t%eval(&b-1) 0 f0-f%eval(&c-1) 100000;
set a;
%do i=%eval(&b-1) %to 1 %by -1 ;
t&i=t%eval(&b-1);
%end;
t0=close;
f0=close;
hh=max(of t0-t%eval(&b-1));
hht=max(0*((t0-hh)=0)%do i=1 %to %eval(&b-1) %by 1;,&i*((t&i-hh)=0)%end;);
%do i=%eval(&c-1) %to 1 %by -1;
f&i=f%eval(&c-1);
%end;
ll=min(of f0-f%eval(&c-1));
llt=max(0*((f0-ll)=0)%do i=1 %to %eval(&c-1) %by 1;,&i*((f&i-ll)=0)%end;);
rh=log(hh)-log(mean(of t0-t%eval(&m-1)));
rl=log(mean(of f0-f%eval(&t-1)))-log(ll);
ls=ll*(1+rh*(&m));
ss=hh*(1-rl*(&t));
keep  date time  ls ss;
data b;
set b;
if date<="10may2010"d and date>="05JUN2007"d+&n;
run;
proc sql;
create table bb as
select b.*,c.lx,c.sx from b join c on b.date=c.date1 and b.time=c.time1
order by date;
quit;
data xx;
set bb;
x=(ls-lx)/lx;
y=(ss-sx)/lx;
keep date time x y;
run;
proc means data=xx;
var x y;
output out=zhishun (drop=_type_ _freq_) mean=meanx meany std=stdx stdy;
run;
data p;
n=&a;
m=&b;
t=&c;
run;
data tt;
merge p zhishun;
run;
proc append base=zhi data=tt force;
run;
%end;
%end;
%end;
%mend;
%t(5,3,3);
再问下，这个程序我想生成一个5*3*3的记录，为什么结果中会有很多数据相同的呢，是不是DO语句控制出现问题了！