mark下 一有时间就来整

我上周在休假，所以抱歉没及时回答。
关于漏服问题是我当时没理解对意思，现在已经解决了。
关于status有一个问题，在你的答案中，3号和4号的status=1, 3号是没问题的。
对于4号来说，这个人的研究期限是10月7号到19号，为期13天，如果这个人的status=1，可以理解为从13号到19号没有服药，正好七天，如果是这样理解的话，那2号的研究期限是10月1号到12号，但这个人最后一次吃药是4号，从5号到12号没有记录，是否status的值也应该是1？

谢谢你对这件事如此上心，我发现根源在于我没有把问题阐述的非常清楚清楚，
status（是否脱失）：连续7天不服药包含7天，如4号10月12号到10月20号，中间11号-19号7天未服药，则status为1。
miss（是否漏服）：断断续续服药，不服药天数小于7天，如4号10月7号服药后，中间8号未服药，9号又开始服药，则4号的状态为服药期间miss=1，最后脱失status=1！
你可能理解为研究期间内累计7天不服药？
后来借鉴了@龙潭丰乐的程序data c;
  set b;
    date1= lag(m_date) ;
   if pid=lag(pid) then
           period=m_date-date1;
   else period=.;
  if period>7 then status=1;
          else         status=0;
   if period>=2 and period<=7 then miss=1;
           else miss=0;
        drop date1;
run;
跑出了想要的结果，不知你的程序是否更简洁，可以学习下！ 谢谢！

    谢谢你的回答，只是其中有些变量不知道是代表哪一行数字，也不知道变量的变换过程，如freqency\quality,可能我理解力有限，还请见谅，不过非常感谢你，我会好好向你学习！

谢谢！欢迎讨论！

我的问题是4号的研究期是10月7号到10月19号，为期13天，不包括20号，数据里那条10月20号是属于超期服药的，就相当于5号的10月23号和11月2号，如果是超期服药，那一条就没有存在的意义了，所以7天的界限不应该把那一天包括进去。这样的话2号和4号就是同样的情况了。

可能我之前没有完全理解你的意思，所以问题一弄的比较复杂。但是这个问题 还挺有意思的

我还有一些有意思的数据，到时候，欢迎讨论！不知道你现在理解了没？其实@wwang111的程序已经比较简洁易懂了，如有高见欢迎继续讨论！

4号的status你是对的，20号超过研究期限了，谢谢指正，miss应该为1吧？

这里的status，如果只考虑研究期限内的数据，我觉得2号和4号应该是属于同一种情况。
miss没有问题，你上次给出的答案是对的，我明天把我的程序粘上来，你再看一下有没有问题。

恩恩  理解了  继续玩转sas，玩转数据

这是我更新后的程序，你看看有什么问题。

data test;
input subjid date: yymmdd10. dose time;
format date yymmdd10.;
cards;
1 2006-9-30 25 1
2 2006-10-1 15 1
2 2006-10-1 18 2
2 2006-10-3 30 1
2 2006-10-4 30 1
3 2006-10-4 30 1
3 2006-10-5 10 1
3 2006-10-13 35 1
4 2006-10-7 30 1
4 2006-10-9 10 1
4 2006-10-12 30 1
4 2006-10-20 30 1
5 2006-10-10 30 1
5 2006-10-11 30 1
5 2006-10-12 10 1
5 2006-10-13 70 1
5 2006-10-14 25 1
5 2006-10-15 30 1
5 2006-10-16 30 1
5 2006-10-17 45 1
5 2006-10-18 30 1
5 2006-10-19 20 1
5 2006-10-20 35 1
5 2006-10-21 35 1
5 2006-10-22 35 1
5 2006-10-23 35 1
5 2006-11-2 35 1
;
* pick up the valid treatment phase;
proc sql;
create table test1 as
select *  from test
group by subjid
having date < min(date)+13
order by subjid,date,time;
quit;
* combine the subjects who dose two times a day;
data test2;
set test1;
by subjid date time;
retain dose_;
if first.date then dose_=dose;
else dose+dose_;
if last.date;
run;
* compare the date and dose from this time to next time;
data test3;
set test2;
by subjid date time;
date1=lag(date);
dose1=lag(dose);
if first.subjid then do; date1=.; dose1=.; end;
if first.subjid and last.subjid then do; date1=date; dose1=dose; flag=1;end;
if date1 ne . and date-date1+1>7 then status=1;
if status=. then status=0;
if date-date1+1<=7 and date-date1>1 then miss=1;
else miss=0;
format date1 fdate yymmdd10.;
drop dose_;
run;

proc sql;
* status, missing dose;
create table status as
select distinct subjid, status
from test3
group by subjid
having status=max(status)
order by subjid;

create table miss as
select distinct subjid, miss
from test3
group by subjid
having miss=max(miss)
order by subjid;

* actual dose date;
create table actdate as
select subjid, count(distinct date) as actdate
from test3
where  date-date1<=7
group by 1
order by 1;

* mean dose;
create table mean as
select distinct subjid, ifn(flag=1,dose,mean(dose)) as mean
from test3
where flag=1 or  dose ne dose1
group by 1
order by 1;

* adjust time;
create table adjtime as
select distinct subjid,ifn(flag=1,0,count(distinct date1)) as adjtime
from test3
where flag=1 or (dose1 ne . and dose ne dose1)
group by 1
order by 1;

* adjust mean;
create table adjmean as
select a.subjid, ifn(n=0,0,(a.n/b.adjtime)) as adjmean from
(select distinct subjid, ifn(flag=1,0,sum(abs(dose-dose1))) as n
from test3
where flag=1 or (dose1 ne . and dose ne dose1)
group by 1) a
join adjtime b
on a.subjid=b.subjid
order by a.subjid;
quit;

* final dateset;
data final;
merge actdate status miss adjtime mean adjmean;
  by subjid;
run;

刚运行了你提供的更新程序，很完美，非常感谢！
查了一下关于奖励论坛币的帖子，非管理权限的会员如我，需要你设置标价的附件，我去购买即可。关于设置：https://bbs.pinggu.org/thread-1155160-1-1.html    请参照这个帖子！  谢谢！

论坛币就不用了